Счет кол. строк и кол. символов по строкам

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Счет кол. строк и кол. символов по строкам (Формулы/Formulas)

4step

Дата: Среда, 24.12.2025, 14:12 | Сообщение № 1

Группа: Пользователи

Ранг: Участник

Сообщений: 91

Репутация: 0 ±

Замечаний: 40% ±

Добрый день!
Возможно ли создать три формулы для определения счета текста в ячейке, как по строкам, так и по определению максимального количества символов и строк? Количество символов и строк может быть множество. Разделение строк ALT+ENTER.
Пример прилагаю.

К сообщению приложен файл: 2385017.xlsx (9.3 Kb)

Ответить

DrMini

Дата: Среда, 24.12.2025, 15:12 | Сообщение № 2

Группа: Модераторы

Ранг: Старожил

Сообщений: 2170

Репутация: 385 ±

Замечаний: 0% ±

Excel LTSC 2024 RUS

Здравствуйте 4step.
Количество строк можно подсчитать такой формулой:

Код

=ЕСЛИ(ЕПУСТО(A2);0;ДЛСТР(A2)-ДЛСТР(ПОДСТАВИТЬ(A2;СИМВОЛ(10);""))+1)

Остальное надо будет подумать после работы.

Ответить

msi2102

Дата: Среда, 24.12.2025, 16:44 | Сообщение № 3

Группа: Проверенные

Ранг: Обитатель

Сообщений: 471

Репутация: 140 ±

Замечаний: 0% ±

Excel 2019

Можно так
количество символов, немного в другом формате, лень думать
[vba]

Код

=ОБЪЕДИНИТЬ("; "& СИМВОЛ(10);1;ЕСЛИОШИБКА(ДЛСТР(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A4;СИМВОЛ(10);"</s><s>")&"</s></t>";"//s"));0))

[/vba]
Или так, только ~~нужно будет последнюю точку с запятой удалить~~ исправил
[vba]

Код

=ОБЪЕДИНИТЬ("; ";1;ЕСЛИОШИБКА(СТРОКА($1:$10)&"="&ЕСЛИОШИБКА(ДЛСТР(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A2;СИМВОЛ(10);"</s><s>")&"</s></t>";"//s"));0);""))

[/vba]
Максимальное количество символов
[vba]

Код

=МАКС(ЕСЛИОШИБКА(ДЛСТР(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A2;СИМВОЛ(10);"</s><s>")&"</s></t>";"//s"));0))

[/vba]
Количество строк

Код

=ДЛСТР(A2)-ДЛСТР(ПОДСТАВИТЬ(A2;СИМВОЛ(10);""))+1

все массивные

К сообщению приложен файл: 4783803.xlsx (10.0 Kb)

Сообщение отредактировал msi2102 - Среда, 24.12.2025, 17:31

Ответить

msi2102

Дата: Среда, 24.12.2025, 17:46 | Сообщение № 4

Группа: Проверенные

Ранг: Обитатель

Сообщений: 471

Репутация: 140 ±

Замечаний: 0% ±

Excel 2019

В предыдущем сообщении если в строке только пробелы, то выдает количество символов 0, так можно исправить:
[vba]

Код

=ОБЪЕДИНИТЬ("; ";1;ЕСЛИОШИБКА(СТРОКА($1:$10)&"="&ЕСЛИОШИБКА(ДЛСТР(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(ПОДСТАВИТЬ(A2;" ";"|");СИМВОЛ(10);"</s><s>")&"</s></t>";"//s"));0);""))

[/vba]

К сообщению приложен файл: 4783803_1.xlsx (10.2 Kb)

Сообщение отредактировал msi2102 - Среда, 24.12.2025, 17:47

Ответить

4step

Дата: Четверг, 25.12.2025, 12:23 | Сообщение № 5

Группа: Пользователи

Ранг: Участник

Сообщений: 91

Репутация: 0 ±

Замечаний: 40% ±

DrMini, msi2102, Благодарю! То что надо! Спасибо большое! =)

Ответить

_Boroda_

Дата: Пятница, 26.12.2025, 12:05 | Сообщение № 6

Группа: Админы

Ранг: Местный житель

Сообщений: 17001

Репутация: 6667 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Рабоче-крестьянскими формулами макс кол-во символов

Код

=МАКС(ДЛСТР(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A2;" ";"_");СИМВОЛ(10);ПОВТОР(" ";999));СТРОКА($1:$99)*999-998;999))))

Сюда

Цитата msi2102, 24.12.2025 в 16:44, в сообщении № 3 (

)

Максимальное количество символов

тоже нужно добавить вторую ПОДСТАВИТЬ, ведь может быть куча пробелов

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

Счет кол. строк и кол. символов по строкам (Формулы/Formulas)

Страница 1 из 1
1