Target = UCase(Target.Value)

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    On Error GoTo SafeExit
    If Target Is Nothing Then Exit Sub
    If Target.CountLarge > 1 Then GoTo SafeExit
    Application.EnableEvents = False

    Dim rng         As Range
    Set rng = Me.Range("B2:P5000")

    If Not Intersect(Target, rng) Is Nothing Then

        If Not IsDate(Target.Value) Then
            
            If VarType(Target.Value) = vbString Then
                Target.Value = UCase$(CStr(Target.Value))
            End If
        
        End If

        AutoFitRow Target
    End If

    If Target.Column = 4 Then
        
        Dim i       As Variant
        i = Application.Match(Target.Value, _
                Sheets("СПИСОК").Range("A1:A100"), 0)

        If Not IsError(i) Then
            Me.Cells(Target.Row, "E").Value = _
                    Sheets("СПИСОК").Cells(i, "B").Value
        End If

    End If

    If Not Intersect(Target, Me.Columns("F:G")) Is Nothing Then

        If Len(Me.Cells(Target.Row, "F").Value) > 0 And _
                Len(Me.Cells(Target.Row, "G").Value) > 0 Then
            Me.Cells(Target.Row, "H").Value = _
                    Me.Cells(Target.Row, "F").Value & " - " & _
                    Me.Cells(Target.Row, "G").Value
        End If

    End If

SafeExit:
    Application.EnableEvents = True
End Sub

Private Sub AutoFitRow(ByVal cell As Range)
    Dim r           As Long
    r = cell.Row

    With Me.Rows(r)
        .AutoFit

        If .RowHeight < 30 Then .RowHeight = 30
        If .RowHeight > 120 Then .RowHeight = 120
    End With

End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    If Target.Column = 13 Then
        Application.CutCopyMode = False
    End If

End Sub