Подсчет слов в диапазоне, в т.ч. одинаковых в одной ячейке

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подсчет слов в диапазоне, в т.ч. одинаковых в одной ячейке (Формулы/Formulas)

Leprotto

Дата: Вторник, 15.03.2016, 18:05 | Сообщение № 1

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 145

Репутация: 2 ±

Замечаний: 0% ±

Excel 2016

Обычный СЧЕТЕСЛИ не видит кол-во слов, если в одной ячейке несколько раз встречается искомое слово.
Дополнительная задача: показывать единицу при любом кол-ве ключевого слова.

К сообщению приложен файл: banany.xlsx (8.7 Kb)

Ответить

MacSieM

Дата: Вторник, 15.03.2016, 18:16 | Сообщение № 2

Группа: Проверенные

Ранг: Участник

Сообщений: 84

Репутация: 18 ±

Замечаний: 0% ±

Excel 2010

На первый вопрос решение такое (формула массивная):

Код

=СУММ(ДЛСТР(A2:C2)-ДЛСТР(ПОДСТАВИТЬ(A2:C2;"банан";"")))/ДЛСТР("банан")

На второй вопрос такое:

Код

=--(СЧЁТЕСЛИ(A7:C7;"яблоко")>0)

Сообщение отредактировал MacSieM - Вторник, 15.03.2016, 18:25

Ответить

Pelena

Дата: Вторник, 15.03.2016, 18:22 | Сообщение № 3

Группа: Админы

Ранг: Местный житель

Сообщений: 19184

Репутация: 4420 ±

Замечаний: ±

Excel 365 & Mac Excel

Варианты формул, обе массивные

Код

=СУММ(--(ПСТР(A2:C2;СТРОКА(1:99);5)="банан"))

Код

=--ИЛИ(ПОИСК("яблоко";A7:C7))

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

Che79

Дата: Вторник, 15.03.2016, 18:28 | Сообщение № 4

Группа: Друзья

Ранг: Старожил

Сообщений: 1649

Репутация: 306 ±

Замечаний: 0% ±

2013 Win, 365 Mac

про бананы - первое, что пришло в голову, не особо думая
массивная

Код

=СЧЁТ(ПОИСК({"бананы":"банан"};A2:C2))

массивная

Код

=СЧЁТ(--ЕСЛИ(A2:C2="бан*";))

хотя, вот эта очень сомнительная

про яблоки
массивная

Код

=ЕСЛИ(ИЛИ(A7:C7="яблоко");1;"")

Делай нормально и будет нормально!

Сообщение отредактировал Che79 - Вторник, 15.03.2016, 19:01

Ответить

Udik

Дата: Вторник, 15.03.2016, 18:38 | Сообщение № 5

Группа: Друзья

Ранг: Старожил

Сообщений: 1588

Репутация: 192 ±

Замечаний: 0% ±

Excel 2016 х 64

или простая, на основе формулы MacSieM

Код

=СУММПРОИЗВ((ДЛСТР(A2:C2)-ДЛСТР(ПОДСТАВИТЬ(A2:C2;"банан";"")))/ДЛСТР("банан"))

и вторая

Код

=--(СУММПРОИЗВ((ДЛСТР(A7:C7)-ДЛСТР(ПОДСТАВИТЬ(A7:C7;"яблоко";""))))>0)

вот вам барабан
яд 41001231307558 wm R419131876897
udik1968@gmail.com

Сообщение отредактировал Udik - Вторник, 15.03.2016, 18:48

Ответить

abtextime

Дата: Вторник, 15.03.2016, 18:45 | Сообщение № 6

Группа: Проверенные

Ранг: Ветеран

Сообщений: 828

Репутация: 117 ±

Замечаний: 0% ±

Excel 2010

а меня на UDF потянуло ...

[vba]

Код

Function Ban(RR As Range, SS As String) As Integer

Dim R As Range, S As String

Ban = 0

For Each R In RR

S = R.Value

Ban = Ban + (Len(S) - Len(Replace(S, SS, ""))) / Len(SS)

Next

End Function

[/vba]

К сообщению приложен файл: _banany.xlsm (13.8 Kb)

Сообщение отредактировал abtextime - Вторник, 15.03.2016, 18:47

Ответить

_Boroda_

Дата: Вторник, 15.03.2016, 20:08 | Сообщение № 7

Группа: Модераторы

Ранг: Местный житель

Сообщений: 16675

Репутация: 6481 ±

Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS

Ну и еще немассивные формулы

Код

=ОТБР(СУММПРОИЗВ(ДЛСТР(ПОДСТАВИТЬ(A2:C2;"банан";ПОВТОР(" ";99))))/99)

Код

=ОТБР(СУММПРОИЗВ(ДЛСТР(ПОДСТАВИТЬ(A2:C2;"банан";ПОВТОР(" ";100))))%)

Во второй слово "яблоко" не обязательно же первое, правильно? Может быть что-то типа "куча яблок стухла"?

Код

=--ЕТЕКСТ(ГПР("*яблок*";A7:C7;1;))

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995