Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Отсортировать по количеству повторяющихся значений. - Мир MS Excel

Регистрация · Логин: · Пароль: · · Забыли пароль?
  • Страница 1 из 1
  • 1
Модератор форума: _Boroda_, Manyasha, SLAVICK, китин  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Отсортировать по количеству повторяющихся значений. (Формулы/Formulas)
Отсортировать по количеству повторяющихся значений.
Kaktus8 Дата: Вторник, 02.04.2019, 18:40 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Уважаемые знатоки Excel,
помогите, пожалуйста, отсортировать данные по количеству их повторений.

В примере:
Лист1 - необходимо посчитать количество повторов значений и вывести их рядом в виде убывающего списка.
Лист2 - то же самое, но в качестве повторяющихся значений уже выступает строчный диапазон ячеек.
К сообщению приложен файл: 3-1a.xlsx(10.3 Kb)


Сообщение отредактировал Kaktus8 - Вторник, 02.04.2019, 18:42
 
Ответить
СообщениеУважаемые знатоки Excel,
помогите, пожалуйста, отсортировать данные по количеству их повторений.

В примере:
Лист1 - необходимо посчитать количество повторов значений и вывести их рядом в виде убывающего списка.
Лист2 - то же самое, но в качестве повторяющихся значений уже выступает строчный диапазон ячеек.

Автор - Kaktus8
Дата добавления - 02.04.2019 в 18:40
Pelena Дата: Вторник, 02.04.2019, 19:28 | Сообщение № 2
Группа: Админы
Ранг: Местный житель
Сообщений: 13866
Репутация: 3041 ±
Замечаний: ±

Excel 2010, 2016 & Mac Excel
Сводная не подойдёт?
К сообщению приложен файл: 9691286.xlsx(28.0 Kb)


"Черт возьми, Холмс! Но как??!!"
ЯД 41001765434816
 
Ответить
СообщениеСводная не подойдёт?

Автор - Pelena
Дата добавления - 02.04.2019 в 19:28
Kaktus8 Дата: Вторник, 02.04.2019, 19:48 | Сообщение № 3
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Большое спасибо за отклик!
Хотелось бы, однако, с помощью формул это решить и, желательно, без промежуточных ячеек.
Если, конечно, это возможно.
 
Ответить
СообщениеБольшое спасибо за отклик!
Хотелось бы, однако, с помощью формул это решить и, желательно, без промежуточных ячеек.
Если, конечно, это возможно.

Автор - Kaktus8
Дата добавления - 02.04.2019 в 19:48
_Boroda_ Дата: Вторник, 02.04.2019, 20:24 | Сообщение № 4
Группа: Модераторы
Ранг: Местный житель
Сообщений: 14864
Репутация: 5881 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Так нужно?
1. число
Код
=-ПРОСМОТР(;-A$2:A$24/(НАИБОЛЬШИЙ(СЧЁТЕСЛИ(A:A;A$2:A$24)+1%%/A$2:A$24;СУММ(B$1:B1)+1)=СЧЁТЕСЛИ(A:A;A$2:A$24)+1%%/A$2:A$24))
кол-во
Код
=СЧЁТЕСЛИ(A:A;C2)

2. цифры
Код
=ЕСЛИ(L2;ИНДЕКС(A:A;ОСТАТ(НАИБОЛЬШИЙ(ЧАСТОТА(МУМНОЖ($A$2:$K$17;10^СТРОКА($1:$11));МУМНОЖ($A$2:$K$17;10^СТРОКА($1:$11)))+СТРОКА($2:$18)%%;СТРОКА(M1));1)/1%%);)
кол-во
Код
=НАИБОЛЬШИЙ(ЧАСТОТА(МУМНОЖ(A$2:K$17;10^СТРОКА($1:$11));МУМНОЖ(A$2:K$17;10^СТРОКА($1:$11)));СТРОКА(L1))


Обе первые формулы массивные, вводятся одновременным нажатием Контрл Шифт Ентер
К сообщению приложен файл: 3-1a_1.xlsx(13.8 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеТак нужно?
1. число
Код
=-ПРОСМОТР(;-A$2:A$24/(НАИБОЛЬШИЙ(СЧЁТЕСЛИ(A:A;A$2:A$24)+1%%/A$2:A$24;СУММ(B$1:B1)+1)=СЧЁТЕСЛИ(A:A;A$2:A$24)+1%%/A$2:A$24))
кол-во
Код
=СЧЁТЕСЛИ(A:A;C2)

2. цифры
Код
=ЕСЛИ(L2;ИНДЕКС(A:A;ОСТАТ(НАИБОЛЬШИЙ(ЧАСТОТА(МУМНОЖ($A$2:$K$17;10^СТРОКА($1:$11));МУМНОЖ($A$2:$K$17;10^СТРОКА($1:$11)))+СТРОКА($2:$18)%%;СТРОКА(M1));1)/1%%);)
кол-во
Код
=НАИБОЛЬШИЙ(ЧАСТОТА(МУМНОЖ(A$2:K$17;10^СТРОКА($1:$11));МУМНОЖ(A$2:K$17;10^СТРОКА($1:$11)));СТРОКА(L1))


Обе первые формулы массивные, вводятся одновременным нажатием Контрл Шифт Ентер

Автор - _Boroda_
Дата добавления - 02.04.2019 в 20:24
Kaktus8 Дата: Вторник, 02.04.2019, 22:08 | Сообщение № 5
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Да! То, что надо!

Только два момента, если можно, поправьте пожалуйтста!
1. Число.
При добавлении в столбец А новых чисел после 24 строки не происходит обновления.
2. Цифры.
В диапазоне M-W, - 3,4,8,9 строчках, последние цифры исчезли.

По пункту 1: я так понял, нужно вместо A$24 (в диапазонах) ввести А$900, например?
На всякий случай спрашиваю, вдруг ещё какая-то тонкость есть.
По пункту 2: по поводу последних цифр, - не могу предположить. Пока не смог разобраться.
По пункту 2: чтобы введённые после 17 строки, также обрабатывались, достаточно вместо $K$17 ввести $K$900, например, и всё?


Сообщение отредактировал Kaktus8 - Вторник, 02.04.2019, 22:18
 
Ответить
СообщениеДа! То, что надо!

Только два момента, если можно, поправьте пожалуйтста!
1. Число.
При добавлении в столбец А новых чисел после 24 строки не происходит обновления.
2. Цифры.
В диапазоне M-W, - 3,4,8,9 строчках, последние цифры исчезли.

По пункту 1: я так понял, нужно вместо A$24 (в диапазонах) ввести А$900, например?
На всякий случай спрашиваю, вдруг ещё какая-то тонкость есть.
По пункту 2: по поводу последних цифр, - не могу предположить. Пока не смог разобраться.
По пункту 2: чтобы введённые после 17 строки, также обрабатывались, достаточно вместо $K$17 ввести $K$900, например, и всё?

Автор - Kaktus8
Дата добавления - 02.04.2019 в 22:08
_Boroda_ Дата: Вторник, 02.04.2019, 22:37 | Сообщение № 6
Группа: Модераторы
Ранг: Местный житель
Сообщений: 14864
Репутация: 5881 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Правильно спрашиваете, конечно есть. Сначала хотел при одинаковом кол-во по возрастанию сделать, ну да ладно
Код
=ЕСЛИОШИБКА(-ПРОСМОТР(;-A$2:A$99/(НАИБОЛЬШИЙ(СЧЁТЕСЛИ(A:A;A$2:A$99)+A$2:A$99%%;СУММ(B$1:B1)+1)=СЧЁТЕСЛИ(A:A;A$2:A$99)+A$2:A$99%%));)

Не, можно и по возрастанию, но тогда усложнится немного. И да, кол-во пустых строк запаса должно быть больше максимального кол-ва повторов. Опять же можно сделать без этого ограничения, но формула усложнится немного
Код
=НАИБОЛЬШИЙ(ЧАСТОТА(МУМНОЖ(--A$2:K$99;10^СТРОКА($1:$11));МУМНОЖ(--A$2:K$99;10^СТРОКА($1:$11)));СТРОКА(L2))

Пропавшие цифры - это я просто $ забыл
Код
=ЕСЛИ($L2;ИНДЕКС(A:A;ОСТАТ(НАИБОЛЬШИЙ(ЧАСТОТА(МУМНОЖ(--$A$2:$K$98;10^СТРОКА($1:$11));МУМНОЖ(--$A$2:$K$98;10^СТРОКА($1:$11)))+СТРОКА($2:$99)%%;СТРОКА(M2));1)/1%%);)

Про кол-во пустых - аналогично
К сообщению приложен файл: 3-1a_2.xlsx(13.7 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеПравильно спрашиваете, конечно есть. Сначала хотел при одинаковом кол-во по возрастанию сделать, ну да ладно
Код
=ЕСЛИОШИБКА(-ПРОСМОТР(;-A$2:A$99/(НАИБОЛЬШИЙ(СЧЁТЕСЛИ(A:A;A$2:A$99)+A$2:A$99%%;СУММ(B$1:B1)+1)=СЧЁТЕСЛИ(A:A;A$2:A$99)+A$2:A$99%%));)

Не, можно и по возрастанию, но тогда усложнится немного. И да, кол-во пустых строк запаса должно быть больше максимального кол-ва повторов. Опять же можно сделать без этого ограничения, но формула усложнится немного
Код
=НАИБОЛЬШИЙ(ЧАСТОТА(МУМНОЖ(--A$2:K$99;10^СТРОКА($1:$11));МУМНОЖ(--A$2:K$99;10^СТРОКА($1:$11)));СТРОКА(L2))

Пропавшие цифры - это я просто $ забыл
Код
=ЕСЛИ($L2;ИНДЕКС(A:A;ОСТАТ(НАИБОЛЬШИЙ(ЧАСТОТА(МУМНОЖ(--$A$2:$K$98;10^СТРОКА($1:$11));МУМНОЖ(--$A$2:$K$98;10^СТРОКА($1:$11)))+СТРОКА($2:$99)%%;СТРОКА(M2));1)/1%%);)

Про кол-во пустых - аналогично

Автор - _Boroda_
Дата добавления - 02.04.2019 в 22:37
Kaktus8 Дата: Среда, 03.04.2019, 00:27 | Сообщение № 7
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Супер! Фантастика просто!
Большущее спасибо!

И да, кол-во пустых строк запаса должно быть больше максимального кол-ва повторов. Опять же можно сделать без этого ограничения, но формула усложнится немного

Не совсем понял, что Вы имеете в виду и о каком ограничении речь.
Вроде всё прекрасно работает. Поясните, пожалуйста.

Единственный момент который я заметил (раньше не обратил внимания), так это то, что при удалении любой строки в столбцах исходных данных (или нескольких строк) со сдвигом ячеек вверх, формулы перестают работать (значение недоступно).
Иногда может потребоваться удалить строку-другую. Если и это можно как-то побороть, то будет просто идеально.
Ну, или как починить в случае поломки?


Сообщение отредактировал Kaktus8 - Среда, 03.04.2019, 00:32
 
Ответить
СообщениеСупер! Фантастика просто!
Большущее спасибо!

И да, кол-во пустых строк запаса должно быть больше максимального кол-ва повторов. Опять же можно сделать без этого ограничения, но формула усложнится немного

Не совсем понял, что Вы имеете в виду и о каком ограничении речь.
Вроде всё прекрасно работает. Поясните, пожалуйста.

Единственный момент который я заметил (раньше не обратил внимания), так это то, что при удалении любой строки в столбцах исходных данных (или нескольких строк) со сдвигом ячеек вверх, формулы перестают работать (значение недоступно).
Иногда может потребоваться удалить строку-другую. Если и это можно как-то побороть, то будет просто идеально.
Ну, или как починить в случае поломки?

Автор - Kaktus8
Дата добавления - 03.04.2019 в 00:27
_Boroda_ Дата: Среда, 03.04.2019, 09:47 | Сообщение № 8
Группа: Модераторы
Ранг: Местный житель
Сообщений: 14864
Репутация: 5881 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Речь о том, что если макс кол-во повторов у Вас 9, а исходных значений 30, то диапазон нужно писать не меньше, чем A$2:A$40. 40-30>9
Кстати, я немного перебдел, на первом личсте это не актуально

Чтобы удалять строки можно было - это особого вида формулы нужны, в которых нет ссылок на возможно удаляемую строку вот так напишите
Код
=ЕСЛИ($L2;ИНДЕКС(A:A;ОСТАТ(НАИМЕНЬШИЙ(ЧАСТОТА(МУМНОЖ(--$A$2:$K$97;10^ТРАНСП(СТОЛБЕЦ(A:K)));МУМНОЖ(--$A$2:$K$97;10^ТРАНСП(СТОЛБЕЦ(A:K))))+СТРОКА($2:$98)%%;ЧСТРОК(A$1:A$98)-СТРОКА());1)/1%%);)

Код
=НАИМЕНЬШИЙ(ЧАСТОТА(МУМНОЖ(--A$2:K$97;10^ТРАНСП(СТОЛБЕЦ(A:K)));МУМНОЖ(--A$2:K$97;10^ТРАНСП(СТОЛБЕЦ(A:K))));ЧСТРОК(A$1:A$98)-СТРОКА())

И здесь уже не нужно будет следить за количеством пустых
К сообщению приложен файл: 3-1a_3.xlsx(13.1 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеРечь о том, что если макс кол-во повторов у Вас 9, а исходных значений 30, то диапазон нужно писать не меньше, чем A$2:A$40. 40-30>9
Кстати, я немного перебдел, на первом личсте это не актуально

Чтобы удалять строки можно было - это особого вида формулы нужны, в которых нет ссылок на возможно удаляемую строку вот так напишите
Код
=ЕСЛИ($L2;ИНДЕКС(A:A;ОСТАТ(НАИМЕНЬШИЙ(ЧАСТОТА(МУМНОЖ(--$A$2:$K$97;10^ТРАНСП(СТОЛБЕЦ(A:K)));МУМНОЖ(--$A$2:$K$97;10^ТРАНСП(СТОЛБЕЦ(A:K))))+СТРОКА($2:$98)%%;ЧСТРОК(A$1:A$98)-СТРОКА());1)/1%%);)

Код
=НАИМЕНЬШИЙ(ЧАСТОТА(МУМНОЖ(--A$2:K$97;10^ТРАНСП(СТОЛБЕЦ(A:K)));МУМНОЖ(--A$2:K$97;10^ТРАНСП(СТОЛБЕЦ(A:K))));ЧСТРОК(A$1:A$98)-СТРОКА())

И здесь уже не нужно будет следить за количеством пустых

Автор - _Boroda_
Дата добавления - 03.04.2019 в 09:47
Kaktus8 Дата: Среда, 03.04.2019, 15:04 | Сообщение № 9
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
И здесь уже не нужно будет следить за количеством пустых

Большое спасибо!
Всё прекрасно работает!

Чтобы удалять строки можно было - это особого вида формулы нужны, в которых нет ссылок на возможно удаляемую строку вот так напишите

Я очень сильно извиняюсь, так как невольно ввёл Вас в заблуждение, написав про "удаление строк". На самом деле я имел в виду "удаление строк данных" из колонки "Наборы данных (11 цифр)", то есть речь шла об удалении не всей строки в таблице, а только ячеек с исходными данными в диапазоне столбцов А-К (например А16-К16) со "сдвигом ячеек вверх". После такой процедуры удаления, ячейки с формулами в диапазоне M-W пишут, что "значение недоступно для формулы".


Сообщение отредактировал Kaktus8 - Среда, 03.04.2019, 15:11
 
Ответить
Сообщение
И здесь уже не нужно будет следить за количеством пустых

Большое спасибо!
Всё прекрасно работает!

Чтобы удалять строки можно было - это особого вида формулы нужны, в которых нет ссылок на возможно удаляемую строку вот так напишите

Я очень сильно извиняюсь, так как невольно ввёл Вас в заблуждение, написав про "удаление строк". На самом деле я имел в виду "удаление строк данных" из колонки "Наборы данных (11 цифр)", то есть речь шла об удалении не всей строки в таблице, а только ячеек с исходными данными в диапазоне столбцов А-К (например А16-К16) со "сдвигом ячеек вверх". После такой процедуры удаления, ячейки с формулами в диапазоне M-W пишут, что "значение недоступно для формулы".

Автор - Kaktus8
Дата добавления - 03.04.2019 в 15:04
_Boroda_ Дата: Среда, 03.04.2019, 15:13 | Сообщение № 10
Группа: Модераторы
Ранг: Местный житель
Сообщений: 14864
Репутация: 5881 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Ох ...
Ловите
Код
=ЕСЛИ($L2;ИНДЕКС(A:A;ОСТАТ(НАИМЕНЬШИЙ(ЧАСТОТА(МУМНОЖ(--$A$2:$K$97;10^ТРАНСП(СТОЛБЕЦ($A$1:$K$1)));МУМНОЖ(--$A$2:$K$97;10^ТРАНСП(СТОЛБЕЦ($A$1:$K$1))))+СТРОКА(A$2:A$98)%%;ЧСТРОК(A$1:A$98)-СТРОКА());1)/1%%);)
К сообщению приложен файл: 3-1a_4.xlsx(13.1 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеОх ...
Ловите
Код
=ЕСЛИ($L2;ИНДЕКС(A:A;ОСТАТ(НАИМЕНЬШИЙ(ЧАСТОТА(МУМНОЖ(--$A$2:$K$97;10^ТРАНСП(СТОЛБЕЦ($A$1:$K$1)));МУМНОЖ(--$A$2:$K$97;10^ТРАНСП(СТОЛБЕЦ($A$1:$K$1))))+СТРОКА(A$2:A$98)%%;ЧСТРОК(A$1:A$98)-СТРОКА());1)/1%%);)

Автор - _Boroda_
Дата добавления - 03.04.2019 в 15:13
Kaktus8 Дата: Среда, 03.04.2019, 15:43 | Сообщение № 11
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Большущее Вам спасибо за помощь!
Всё идеально!
Низкий поклон!
yes
 
Ответить
СообщениеБольшущее Вам спасибо за помощь!
Всё идеально!
Низкий поклон!
yes

Автор - Kaktus8
Дата добавления - 03.04.2019 в 15:43
Kaktus8 Дата: Среда, 03.04.2019, 19:36 | Сообщение № 12
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Кхм... Мне ужасно неловко опять беспокоить,
но обнаружился такой момент:
на Листе 1 формула перестаёт работать, если число больше 4 знаков (разрядов), а нужно, хотя-бы 16.
Пробовал форматы ячеек менять, но ничего не помогает.
Ума не приложу, как с этим быть. Посоветуйте, пожалуйста!


Сообщение отредактировал Kaktus8 - Среда, 03.04.2019, 19:43
 
Ответить
СообщениеКхм... Мне ужасно неловко опять беспокоить,
но обнаружился такой момент:
на Листе 1 формула перестаёт работать, если число больше 4 знаков (разрядов), а нужно, хотя-бы 16.
Пробовал форматы ячеек менять, но ничего не помогает.
Ума не приложу, как с этим быть. Посоветуйте, пожалуйста!

Автор - Kaktus8
Дата добавления - 03.04.2019 в 19:36
_Boroda_ Дата: Среда, 03.04.2019, 19:53 | Сообщение № 13
Группа: Модераторы
Ранг: Местный житель
Сообщений: 14864
Репутация: 5881 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Ничего не знаю, какой пример - такой ответ. Будет пример с числом в 16 знаков (что в Excel в принципе невозможно, 15 максимум), будет и ответ


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеНичего не знаю, какой пример - такой ответ. Будет пример с числом в 16 знаков (что в Excel в принципе невозможно, 15 максимум), будет и ответ

Автор - _Boroda_
Дата добавления - 03.04.2019 в 19:53
Kaktus8 Дата: Среда, 03.04.2019, 20:01 | Сообщение № 14
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Просто на Лист1, столбец А ("Данные"), если ввести, например, "11111111111", то сортировка по частоте уже не работает.
Хотя-бы для для 11 разрядов как-то настроить (имеются в виду разряды только ДО запятой).
Файл тот-же (Ваш последний).


Сообщение отредактировал Kaktus8 - Среда, 03.04.2019, 20:03
 
Ответить
СообщениеПросто на Лист1, столбец А ("Данные"), если ввести, например, "11111111111", то сортировка по частоте уже не работает.
Хотя-бы для для 11 разрядов как-то настроить (имеются в виду разряды только ДО запятой).
Файл тот-же (Ваш последний).

Автор - Kaktus8
Дата добавления - 03.04.2019 в 20:01
_Boroda_ Дата: Среда, 03.04.2019, 20:45 | Сообщение № 15
Группа: Модераторы
Ранг: Местный житель
Сообщений: 14864
Репутация: 5881 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Эта формула с 11-значными числами будет работать только если макс кол-во повторов в массиве не больше 999. А лучше 99. Да и то в 14-15-м знаке могут быть косяки из-за округления перевода двоичной-десятичной систем
Замените %% на *10^-11
Код
=ЕСЛИОШИБКА(-ПРОСМОТР(;-A$2:A$32/(НАИБОЛЬШИЙ(СЧЁТЕСЛИ(A:A;A$2:A$32)+A$2:A$32*10^-11;СУММ(B$1:B1)+1)=СЧЁТЕСЛИ(A:A;A$2:A$32)+A$2:A$32*10^-11));)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеЭта формула с 11-значными числами будет работать только если макс кол-во повторов в массиве не больше 999. А лучше 99. Да и то в 14-15-м знаке могут быть косяки из-за округления перевода двоичной-десятичной систем
Замените %% на *10^-11
Код
=ЕСЛИОШИБКА(-ПРОСМОТР(;-A$2:A$32/(НАИБОЛЬШИЙ(СЧЁТЕСЛИ(A:A;A$2:A$32)+A$2:A$32*10^-11;СУММ(B$1:B1)+1)=СЧЁТЕСЛИ(A:A;A$2:A$32)+A$2:A$32*10^-11));)

Автор - _Boroda_
Дата добавления - 03.04.2019 в 20:45
Kaktus8 Дата: Среда, 03.04.2019, 21:15 | Сообщение № 16
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Эта формула с 11-значными числами будет работать только если макс кол-во повторов в массиве не больше 999. А лучше 99.

Спасибо!
Надо же, какие тонкости - даже в голову не придёт.
Ну, хотя-бы так, - тоже неплохо.
А под "не больше 999 повторов в массиве" имеется в виду общее количество повторов для всех цифр или максимальное их количество для одной цифры? И единичные повторы тоже нужно учитывать?
 
Ответить
Сообщение
Эта формула с 11-значными числами будет работать только если макс кол-во повторов в массиве не больше 999. А лучше 99.

Спасибо!
Надо же, какие тонкости - даже в голову не придёт.
Ну, хотя-бы так, - тоже неплохо.
А под "не больше 999 повторов в массиве" имеется в виду общее количество повторов для всех цифр или максимальное их количество для одной цифры? И единичные повторы тоже нужно учитывать?

Автор - Kaktus8
Дата добавления - 03.04.2019 в 21:15
_Boroda_ Дата: Среда, 03.04.2019, 21:29 | Сообщение № 17
Группа: Модераторы
Ранг: Местный житель
Сообщений: 14864
Репутация: 5881 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Для одного числа


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеДля одного числа

Автор - _Boroda_
Дата добавления - 03.04.2019 в 21:29
Kaktus8 Дата: Среда, 03.04.2019, 21:50 | Сообщение № 18
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Тогда всё хорошо. У меня вряд-ли наберётся больше сотни повторов.
Ещё раз, большущее спасибо!
 
Ответить
СообщениеТогда всё хорошо. У меня вряд-ли наберётся больше сотни повторов.
Ещё раз, большущее спасибо!

Автор - Kaktus8
Дата добавления - 03.04.2019 в 21:50
_Boroda_ Дата: Среда, 03.04.2019, 21:58 | Сообщение № 19
Группа: Модераторы
Ранг: Местный житель
Сообщений: 14864
Репутация: 5881 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Смотрите, я про косяки предупредил. В следующий раз давайте пример, максимально приближенный к реальности и описывайте свои возможные действия с файлом. А то видите, сколько мы раз одно и то же переделывали?


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеСмотрите, я про косяки предупредил. В следующий раз давайте пример, максимально приближенный к реальности и описывайте свои возможные действия с файлом. А то видите, сколько мы раз одно и то же переделывали?

Автор - _Boroda_
Дата добавления - 03.04.2019 в 21:58
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Отсортировать по количеству повторяющихся значений. (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс цитирования
© 2010-2019 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!