Sub Вывести_нижнюю()

    Dim sh1 As Worksheet, sh2 As Worksheet, shRes As Worksheet
    Dim r1 As Long, r2 As Long, j As Long
    
    Set sh1 = Worksheets("Лист1")
    Set sh2 = Worksheets("Лист2")
    Set shRes = Worksheets("Формула")
    
    shRes.Range("C12:E12").ClearContents
    
    r1 = sh1.Cells(sh1.Rows.Count, "D").End(xlUp).Row
    r2 = sh2.Cells(sh2.Rows.Count, "D").End(xlUp).Row
    
    Do
        If r1 = 1 And r2 = 1 Then
            Exit Do
        End If
        
        If r1 > 1 Then
            If Проверка_строки(sh1.Cells(r1, "D").Resize(, 3), shRes) = True Then
                Exit Do
            End If
            r1 = r1 - 1
        End If
        
        If r2 > 1 Then
            If Проверка_строки(sh2.Cells(r2, "D").Resize(, 3), shRes) = True Then
                Exit Do
            End If
            r2 = r2 - 1
        End If
    Loop
    
    MsgBox "Готово!", vbInformation

End Sub

Private Function Проверка_строки(objRow As Range, shRes As Worksheet) As Boolean
    
    Dim j As Long
    
    For j = 1 To objRow.Cells.Count
        If objRow.Cells(1, j).Value <= 0 Then
            Exit Function
        End If
    Next j
    
    shRes.Range("C12:E12").Value = objRow.Value
    Проверка_строки = True

End Function