Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Количество фраз по цифровому значению - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Количество фраз по цифровому значению (Формулы/Formulas)
Количество фраз по цифровому значению
KostyanBr Дата: Суббота, 19.10.2019, 22:09 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 28
Репутация: 0 ±
Замечаний: 20% ±

Excel 2013
Здравствуйте. Возможно ли сделать количество слов (фраз) в отдельную колонку определенное количество раз.
В колонке 1 идет прописаны фразы, в колонке 2 прописано сколько раз должна быть прописана эта фраза, в колонке три должны быть эти фразы
https://yadi.sk/i/ecsSr8HwCFLpTA
К сообщению приложен файл: 1244562.xlsx (8.2 Kb)
 
Ответить
СообщениеЗдравствуйте. Возможно ли сделать количество слов (фраз) в отдельную колонку определенное количество раз.
В колонке 1 идет прописаны фразы, в колонке 2 прописано сколько раз должна быть прописана эта фраза, в колонке три должны быть эти фразы
https://yadi.sk/i/ecsSr8HwCFLpTA

Автор - KostyanBr
Дата добавления - 19.10.2019 в 22:09
Светлый Дата: Воскресенье, 20.10.2019, 00:38 | Сообщение № 2
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
Здравствуйте!
Если с первой строки начинать, то такая формула в столбце C:
Код
=ЕСЛИОШИБКА(ЕСЛИ(СТРОКА()=1;A1;""&ИНДЕКС(A:A;ПОИСКПОЗ(СМЕЩ(C$1;СТРОКА()-2;);A:A;)+(ВПР(СМЕЩ(C$1;СТРОКА()-2;);A:B;2;)=СЧЁТЕСЛИ(СМЕЩ(C$1;;;СТРОКА()-1);СМЕЩ(C$1;СТРОКА()-2;)));));"")
Если начать можно со второй строки, то формула в столбце Е проще:
Код
=ЕСЛИ(E1>"";""&ЕСЛИОШИБКА(ИНДЕКС(A:A;(СЧЁТЕСЛИ(E$1:E1;E1)=ВПР(E1;A:B;2;))+ПОИСКПОЗ(E1;A:A;));A1);"")
*Даже ещё проще:
Код
=""&ЕСЛИОШИБКА(ИНДЕКС(A:A;(СЧЁТЕСЛИ(E$1:E1;E1)=ВПР(E1;A:B;2;))+ПОИСКПОЗ(E1;A:A;));A1)
Файл перезалил.
**Или формула массива (вводится одновременным нажатием Ctrl+Shift+Enter):
Код
=ЕСЛИОШИБКА(ИНДЕКС(A:A;ПОИСКПОЗ(0=0;СЧЁТЕСЛИ(F$1:F1;A$1:A$7)<B$1:B$7;));"")
К сообщению приложен файл: 1244562-1.xlsx (10.6 Kb)


Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Воскресенье, 20.10.2019, 01:05
 
Ответить
СообщениеЗдравствуйте!
Если с первой строки начинать, то такая формула в столбце C:
Код
=ЕСЛИОШИБКА(ЕСЛИ(СТРОКА()=1;A1;""&ИНДЕКС(A:A;ПОИСКПОЗ(СМЕЩ(C$1;СТРОКА()-2;);A:A;)+(ВПР(СМЕЩ(C$1;СТРОКА()-2;);A:B;2;)=СЧЁТЕСЛИ(СМЕЩ(C$1;;;СТРОКА()-1);СМЕЩ(C$1;СТРОКА()-2;)));));"")
Если начать можно со второй строки, то формула в столбце Е проще:
Код
=ЕСЛИ(E1>"";""&ЕСЛИОШИБКА(ИНДЕКС(A:A;(СЧЁТЕСЛИ(E$1:E1;E1)=ВПР(E1;A:B;2;))+ПОИСКПОЗ(E1;A:A;));A1);"")
*Даже ещё проще:
Код
=""&ЕСЛИОШИБКА(ИНДЕКС(A:A;(СЧЁТЕСЛИ(E$1:E1;E1)=ВПР(E1;A:B;2;))+ПОИСКПОЗ(E1;A:A;));A1)
Файл перезалил.
**Или формула массива (вводится одновременным нажатием Ctrl+Shift+Enter):
Код
=ЕСЛИОШИБКА(ИНДЕКС(A:A;ПОИСКПОЗ(0=0;СЧЁТЕСЛИ(F$1:F1;A$1:A$7)<B$1:B$7;));"")

Автор - Светлый
Дата добавления - 20.10.2019 в 00:38
KostyanBr Дата: Воскресенье, 20.10.2019, 07:32 | Сообщение № 3
Группа: Пользователи
Ранг: Новичок
Сообщений: 28
Репутация: 0 ±
Замечаний: 20% ±

Excel 2013
Спасибо. Все отлично. Написал в ЛС.
 
Ответить
СообщениеСпасибо. Все отлично. Написал в ЛС.

Автор - KostyanBr
Дата добавления - 20.10.2019 в 07:32
KostyanBr Дата: Воскресенье, 20.10.2019, 08:01 | Сообщение № 4
Группа: Пользователи
Ранг: Новичок
Сообщений: 28
Репутация: 0 ±
Замечаний: 20% ±

Excel 2013
Сейчас заметил, что если число 0, либо пустая ячейка с цифрой, то до конца столбца заполняется этим значением, а нужно вообще не прописывать
https://yadi.sk/i/HC7jxMzN7Jsa6g
 
Ответить
СообщениеСейчас заметил, что если число 0, либо пустая ячейка с цифрой, то до конца столбца заполняется этим значением, а нужно вообще не прописывать
https://yadi.sk/i/HC7jxMzN7Jsa6g

Автор - KostyanBr
Дата добавления - 20.10.2019 в 08:01
bmv98rus Дата: Воскресенье, 20.10.2019, 09:46 | Сообщение № 5
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4099
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
Код
=IFERROR(INDEX(A:A;MATCH(1=1;MMULT(--(ROW(B1:B4)>=TRANSPOSE(ROW(B1:B4)));$B$1:$B$4)>=ROW();));"")

или принцип тот же но полегче для вычислений, когда уже ничего не нужно выводить
Код
=IF(ROW()>SUM(B:B);"";INDEX(A:A;MATCH(1=1;MMULT(--(ROW(B1:B4)>=TRANSPOSE(ROW(B1:B4)));$B$1:$B$4)>=ROW();)))
К сообщению приложен файл: Copy_of_1211.xlsx (11.5 Kb)


Замечательный Временно просто медведь , процентов на 20.
 
Ответить
Сообщение
Код
=IFERROR(INDEX(A:A;MATCH(1=1;MMULT(--(ROW(B1:B4)>=TRANSPOSE(ROW(B1:B4)));$B$1:$B$4)>=ROW();));"")

или принцип тот же но полегче для вычислений, когда уже ничего не нужно выводить
Код
=IF(ROW()>SUM(B:B);"";INDEX(A:A;MATCH(1=1;MMULT(--(ROW(B1:B4)>=TRANSPOSE(ROW(B1:B4)));$B$1:$B$4)>=ROW();)))

Автор - bmv98rus
Дата добавления - 20.10.2019 в 09:46
Светлый Дата: Воскресенье, 20.10.2019, 11:34 | Сообщение № 6
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
а нужно вообще не прописывать
Последняя формула лишена этого недостатка, но начинает работать только со второй строки. Заголовок столбца может быть любой.
Или массивная формула, которая будет работать с первой строки:
Код
=ЕСЛИОШИБКА(ЕСЛИ(СТРОКА()=1;A1;ИНДЕКС(A:A;ПОИСКПОЗ(0=0;СЧЁТЕСЛИ(СМЕЩ(G$1;;;СТРОКА()-1;);A$1:A$7)<B$1:B$7;)));"")
*Или чуть короче:
Код
=ЕСЛИ(A$1=A1;A1;""&ЕСЛИОШИБКА(ИНДЕКС(A:A;ПОИСКПОЗ(0=0;СЧЁТЕСЛИ(СМЕЩ(G$1;;;СТРОКА()-1;);A$1:A$7)<B$1:B$7;));))
**Или так:
Код
=""&ЕСЛИОШИБКА(ИНДЕКС(A:A;ПОИСКПОЗ(0=0;СЧЁТЕСЛИ(СМЕЩ(G$1;;;СТРОКА()-1;);A$1:A$7)<B$1:B$7;));A1)
***Добавил файл.
К сообщению приложен файл: 1244562-2.xlsx (14.1 Kb)


Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Воскресенье, 20.10.2019, 12:24
 
Ответить
Сообщение
а нужно вообще не прописывать
Последняя формула лишена этого недостатка, но начинает работать только со второй строки. Заголовок столбца может быть любой.
Или массивная формула, которая будет работать с первой строки:
Код
=ЕСЛИОШИБКА(ЕСЛИ(СТРОКА()=1;A1;ИНДЕКС(A:A;ПОИСКПОЗ(0=0;СЧЁТЕСЛИ(СМЕЩ(G$1;;;СТРОКА()-1;);A$1:A$7)<B$1:B$7;)));"")
*Или чуть короче:
Код
=ЕСЛИ(A$1=A1;A1;""&ЕСЛИОШИБКА(ИНДЕКС(A:A;ПОИСКПОЗ(0=0;СЧЁТЕСЛИ(СМЕЩ(G$1;;;СТРОКА()-1;);A$1:A$7)<B$1:B$7;));))
**Или так:
Код
=""&ЕСЛИОШИБКА(ИНДЕКС(A:A;ПОИСКПОЗ(0=0;СЧЁТЕСЛИ(СМЕЩ(G$1;;;СТРОКА()-1;);A$1:A$7)<B$1:B$7;));A1)
***Добавил файл.

Автор - Светлый
Дата добавления - 20.10.2019 в 11:34
bmv98rus Дата: Воскресенье, 20.10.2019, 12:23 | Сообщение № 7
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4099
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
Светлый, не писал я такого :-) .
Ой как летуче получается с OFFSET, короче, но летучее.


Замечательный Временно просто медведь , процентов на 20.
 
Ответить
СообщениеСветлый, не писал я такого :-) .
Ой как летуче получается с OFFSET, короче, но летучее.

Автор - bmv98rus
Дата добавления - 20.10.2019 в 12:23
Светлый Дата: Воскресенье, 20.10.2019, 12:49 | Сообщение № 8
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
либо пустая ячейка с цифрой
Вот это раньше не протестировал. В файле в зелёных исправлено. Правда пришлось в формате ячейки 0 скрывать.
К сообщению приложен файл: 1244562-3.xlsx (14.3 Kb)


Программировать проще, чем писать стихи.
 
Ответить
Сообщение
либо пустая ячейка с цифрой
Вот это раньше не протестировал. В файле в зелёных исправлено. Правда пришлось в формате ячейки 0 скрывать.

Автор - Светлый
Дата добавления - 20.10.2019 в 12:49
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Количество фраз по цифровому значению (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!