Если в ячейке перед числом знак < то итог 0

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Если в ячейке перед числом знак < то итог 0 (Формулы/Formulas)

DrMini

Дата: Среда, 29.04.2020, 11:59 | Сообщение № 1

Группа: Модераторы

Ранг: Старожил

Сообщений: 2043

Репутация: 316 ±

Замечаний: 0% ±

Excel LTSC 2024 RUS

Доброго времени суток форумчане и гости форума.
Если в ячейке перед числом стоит знак < то в итоге должен для счёта использоваться 0(ноль).
Если > то знак не учитывается и берётся для счёта только число после знака.
Если никакого знака нет то счёт ведётся, как обычно.
Прикрепил пример.
В ячейках C2;C3;C4 вписал что должно получиться.

К сообщению приложен файл: 20042901.xlsx (9.6 Kb)

Сообщение отредактировал DrMini - Среда, 29.04.2020, 11:59

Ответить

_Boroda_

Дата: Среда, 29.04.2020, 12:14 | Сообщение № 2

Группа: Админы

Ранг: Местный житель

Сообщений: 16885

Репутация: 6599 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Можно через ЕСЛИ, но это не интересно. Да и для кучи столбцов (а вдруг их не два) заманаешься писать
Вот такой вариант для любого кол-ва столбцов

=СУММПРОИЗВ(--ТЕКСТ(ПСТР(A2:B2;1+(ЛЕВБ(A2:B2)=">")+9*(ЛЕВБ(A2:B2)="<");9);"Основной;;;\0"))

А с Если примерно так можно

=ЕСЛИ(ЛЕВБ(A2)="<";;ЕСЛИ(ЛЕВБ(A2)=">";ПСТР(A2;2;9);A2))+ЕСЛИ(ЛЕВБ(B2)="<";;ЕСЛИ(ЛЕВБ(B2)=">";ПСТР(B2;2;9);B2))

Хотя здесь вариантов масса
Еще вариант формулой массива

=СУММ(--ЕСЛИ(ЛЕВБ(A2:B2)="<";;ЕСЛИ(ЛЕВБ(A2:B2)=">";ПСТР(A2:B2;2;9);A2:B2)))

И еще

=СУММ(A2:B2;--ЕСЛИ(ЛЕВБ(A2:B2)=">";ПСТР(A2:B2;2;9)))

=СУММ(ЕСЛИОШИБКА(--ПОДСТАВИТЬ(A2:B2;">";);))

И еще немассивный

=СУММПРОИЗВ(--ТЕКСТ(ПОДСТАВИТЬ(A2:B2;">";);"Основной;;;\0"))

К сообщению приложен файл: 20042901_3.xlsx (10.2 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995