Извлечь дату из текста в цифровом формате - Мир MS Excel

Регистрация

Напомнить пароль

= Мир MS Excel/Извлечь дату из текста в цифровом формате - Мир MS Excel

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Извлечь дату из текста в цифровом формате (Формулы/Formulas)

Извлечь дату из текста в цифровом формате

Дата: Четверг, 28.01.2021, 17:06 | Сообщение № 1

Группа: Пользователи

Ранг: Прохожий

Сообщений: 6

Репутация: 1 ±

Замечаний: 0% ±

Excel 2010

Добрый день. Подскажите пожалуйста, нужна формула для извлечения даты из текста в цифровом формате в отдельную ячейку. Во вложении мое решение, дату извлекла, НО она в тексте, поправьте пожалуйста. Заранее благодарю.

К сообщению приложен файл: ___.xlsx (10.6 Kb)

Ответить

Дата: Четверг, 28.01.2021, 17:18 | Сообщение № 2

Группа: Друзья

Ранг: Экселист

Сообщений: 9185

Репутация: 2448 ±

Замечаний: 0% ±

Excel 2010

Код

=ДАТА(ЛЕВБ(ПРАВБ(B2;7);4);ПОИСК(ЛЕВБ(ПРАВБ(B2;11);2);"цнвеварпраяюнюлвгенктояек")/2;ЛЕВБ(ПРАВБ(B2;15);2))

ЮMoney 41001841029809

Ответить

Дата: Четверг, 28.01.2021, 17:20 | Сообщение № 3

Группа: Админы

Ранг: Местный житель

Сообщений: 16475

Репутация: 2750 ±

Замечаний: ±

Excel 2016

Здравствуйте

Формулу можно значительно сократить, но эта тоже рабочая:

Код

=ДАТА(ПРАВБ(ПСТР(B2;ПОИСК("от ";B2)+3;ДЛСТР(B2)-ПОИСК("от ";B2)-5);4);ПОИСКПОЗ(ПСТР(ПСТР(B2;ПОИСК("от ";B2)+3;ДЛСТР(B2)-ПОИСК("от ";B2)-5);4;ДЛСТР(ПСТР(B2;ПОИСК("от ";B2)+3;ДЛСТР(B2)-ПОИСК("от ";B2)-5))-8);{"января":"февраля":"марта":"апреля":"мая":"июня":"июля":"августа":"сентября":"октября":"ноября":"декабря"};);ЛЕВБ(ПСТР(B2;ПОИСК("от ";B2)+3;ДЛСТР(B2)-ПОИСК("от ";B2)-5);2))

Цитата Nic70y, 28.01.2021 в 17:18, в сообщении № 2 ()

Код

=ДАТА(ЛЕВБ(ПРАВБ(B2;7);4);ПОИСК(ЛЕВБ(ПРАВБ(B2;11);2);"цнвеварпраяюнюлвгенктояек")/2;ЛЕВБ(ПРАВБ(B2;15);2))

Ник, в названии месяцев разное кол-во букв...

ЮMoney:41001419691823 | WMR:126292472390

Ответить

Дата: Четверг, 28.01.2021, 17:26 | Сообщение № 4

Группа: Друзья

Ранг: Экселист

Сообщений: 9185

Репутация: 2448 ±

Замечаний: 0% ±

Excel 2010

Цитата Serge_007, 28.01.2021 в 17:20, в сообщении № 3 ()

в названии месяцев разное кол-во букв

блин точно,
рабочий день заканчивается,
шо попало написал,
завтра исправлю (наверное)

ЮMoney 41001841029809

Ответить

Дата: Четверг, 28.01.2021, 18:12 | Сообщение № 5

Группа: Пользователи

Ранг: Прохожий

Сообщений: 6

Репутация: 1 ±

Замечаний: 0% ±

Excel 2010

К сожалению, предложенные формулы у меня не работают(((.

Ответить

Дата: Четверг, 28.01.2021, 20:05 | Сообщение № 6

Группа: Админы

Ранг: Местный житель

Сообщений: 19569

Репутация: 4646 ±

Замечаний: ±

Excel 365 & Mac Excel

Ещё вариант

Код

=--(ПОДСТАВИТЬ(ПСТР(B2;ПОИСК("от ";B2)+3;ПОИСК(" ";B2;ПОИСК("от ";B2)+3)-ПОИСК("от ";B2)+1);"мая";"май")&" "&ЛЕВБ(ПРАВБ(B2;7);4))

К сообщению приложен файл: 4632448.xlsx (11.6 Kb)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

Дата: Четверг, 28.01.2021, 20:12 | Сообщение № 7

Группа: Админы

Ранг: Местный житель

Сообщений: 16475

Репутация: 2750 ±

Замечаний: ±

Excel 2016

Цитата SElenaS, 28.01.2021 в 18:12, в сообщении № 5
К сожалению, предложенные формулы у меня не работают((([/quote ()

А Вы их в свой файл вставьте, тогда будут работать

ЮMoney:41001419691823 | WMR:126292472390

Ответить

Дата: Четверг, 28.01.2021, 20:13 | Сообщение № 8

Группа: Проверенные

Ранг: Ветеран

Сообщений: 534

Репутация: 196 ±

Замечаний: 0% ±

Excel 2013/2016

SElenaS,
Проверил формулу из сообщения №3 - точно работает. Другие не смотрел. Наверное проблема из-за ваших региональных настроек. Попробуйте

Код

{"января":"февраля":"марта":"апреля":"мая":"июня":"июля":"августа":"сентября":"октября":"ноября":"декабря"}

заменить на:

Код

{"января"\"февраля"\"марта"\"апреля"\"мая"\"июня"\"июля"\"августа"\"сентября"\"октября"\"ноября"\"декабря"}

И еще вариант.

Код

=DATE(TRIM(MID(SUBSTITUTE(B2," ",REPT(" ",99)),800,100)),MATCH(TRIM(MID(SUBSTITUTE(B2," ",REPT(" ",99)),700,100)),M,0),TRIM(MID(SUBSTITUTE(B2," ",REPT(" ",99)),600,100)))

Буква М - это именованный диапазон на листе2 с перечнем месяцев.

К сообщению приложен файл: 1111.xlsx (11.1 Kb)

Сообщение отредактировал Egyptian - Четверг, 28.01.2021, 21:31

Ответить

Дата: Пятница, 29.01.2021, 08:36 | Сообщение № 9

Группа: Друзья

Ранг: Экселист

Сообщений: 9185

Репутация: 2448 ±

Замечаний: 0% ±

Excel 2010

RU

Код

=--(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(B2;"мая";"май");"июня";"июнь");"июля";"июль");ПОИСК("от ";B2)+2;7)&ЛЕВБ(ПРАВБ(B2;8);5)))

+

Код

=ДАТА(ЛЕВБ(ПРАВБ(B2;7);4);ПОИСК(ПСТР(B2;ПОИСК("от ";B2)+(--ПСТР(ПОДСТАВИТЬ(B2;0;1);ПОИСК("от ";B2)+3;2)>9)+6;2);"цнвеварпраяюнюлвгенктояек")/2;ПСТР(B2;ПОИСК("от ";B2)+3;2))

АпДэйт

Код

=ДАТА(ЛЕВБ(ПРАВБ(B2;7);4);ПОИСК(ПСТР(B2;ПОИСК("от";B2)+(ПСТР(B2;ПОИСК("от";B2)+5;1)=" ")+6;2);"цнвеварпраяюнюлвгенктояек")/2;ПСТР(B2;ПОИСК("от";B2)+3;2))

Код

=ДАТА(ЛЕВБ(ПРАВБ(B2;7);4);ПОИСК(ПСТР(B2;ПОИСК("\";ПОДСТАВИТЬ(B2;" ";"\";7))+2;2);"цнвеварпраяюнюлвгенктояек")/2;ПСТР(B2;ПОИСК("от";B2)+3;2))

К сообщению приложен файл: 779.xlsx (11.9 Kb)

ЮMoney 41001841029809

Сообщение отредактировал Nic70y - Пятница, 29.01.2021, 11:51

Ответить

Дата: Пятница, 29.01.2021, 14:29 | Сообщение № 10

Группа: Админы

Ранг: Местный житель

Сообщений: 16475

Репутация: 2750 ±

Замечаний: ±

Excel 2016

Цитата Pelena, 28.01.2021 в 20:05, в сообщении № 6 ()

Ещё вариант

Код

=--(ПОДСТАВИТЬ(ПСТР(B2;ПОИСК("от ";B2)+3;ПОИСК(" ";B2;ПОИСК("от ";B2)+3)-ПОИСК("от ";B2)+1);"мая";"май")&" "&ЛЕВБ(ПРАВБ(B2;7);4))

Добавил вариант

Код

=--(ПСТР(B2;НАЙТИ("от ";B2)+3;2)&"."&ПОИСК(ПСТР(B2;НАЙТИ("от ";B2)+7;2);"Ынвеварпраяюнюлвгенктояек")/2&"."&ПСТР(B2;ДЛСТР(B2)-6;4))

и собрал их в файле

К сообщению приложен файл: 20210129_SElena.xls (31.5 Kb)

ЮMoney:41001419691823 | WMR:126292472390

Ответить

Дата: Пятница, 29.01.2021, 18:45 | Сообщение № 11

Группа: Админы

Ранг: Местный житель

Сообщений: 19569

Репутация: 4646 ±

Замечаний: ±

Excel 365 & Mac Excel

Цитата Serge_007, 29.01.2021 в 14:29, в сообщении № 10 ()

собрал их в файле

не все варианты работают с однозначными числами

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

Дата: Пятница, 29.01.2021, 18:52 | Сообщение № 12

Группа: Пользователи

Ранг: Прохожий

Сообщений: 6

Репутация: 1 ±

Замечаний: 0% ±

Excel 2010

Друзья, ОГРОМНОЕ ЧЕЛОВЕЧЕСКОЕ СПАСИБО! Я тронута до глубины души, что сколько молодых людей не прошли мимо просьбы бабушки-старушки и ее проблемы. Всем безмерно благодарна за помощь! У меня действительно какие-то настройки , что я вижу все по другому (см. вложение), но главное мне подошли формулы и списка предложенных и все работает отлично! УДАЧИ ВСЕМ ЗДОРОВЬЯ И УСПЕХА!!!

К сообщению приложен файл: 9724015.xls (31.5 Kb) · 3814112.jpg (37.4 Kb)

Ответить

Дата: Пятница, 29.01.2021, 21:33 | Сообщение № 13

Группа: Друзья

Ранг: Старожил

Сообщений: 1880

Репутация: 543 ±

Замечаний: 0% ±

Excel 2013, 2016

Serge_007, можете добавить в коллекцию ещё один вариант:

Код

=АГРЕГАТ(14;6;--ПОДСТАВИТЬ(ПСТР(B2;ПОИСК("от";B2)+3;{5;6})&ЛЕВБ(ПРАВБ(B2;8);5);"ая";"ай");1)

*Можно ещё так:

Код

=-ПРОСМОТР(;-ПОДСТАВИТЬ(ПСТР(B2;ПОИСК("от";B2)+3;{5;6})&ЛЕВБ(ПРАВБ(B2;8);5);"ая";"ай"))

Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Суббота, 30.01.2021, 01:03

Ответить

Дата: Понедельник, 01.02.2021, 09:10 | Сообщение № 14

Группа: Админы

Ранг: Местный житель

Сообщений: 16475

Репутация: 2750 ±

Замечаний: ±

Excel 2016

Цитата Pelena, 29.01.2021 в 18:45, в сообщении № 11 ()

не все варианты работают с однозначными числами

Лена, в делопроизводстве есть правило - значимые разряды чисел не могут быть пустыми. Т.е. в документах номер квартала всегда будет из одного разряда, год - всегда из четырех, месяцы, дни, часы и минуты - всегда из двух

Цитата Светлый, 29.01.2021 в 21:33, в сообщении № 13 ()

добавить в коллекцию ещё один вариант

Сергей, спасибо!
Добавлю обязательно
Думаю статью написать на эту тему, уверен - задача часто встречается у тех, кто работает с выгрузками из разного рода СУБД (1С, SAP, Oracle и т.п.)

ЮMoney:41001419691823 | WMR:126292472390

Ответить

Дата: Понедельник, 01.02.2021, 09:13 | Сообщение № 15

Группа: Друзья

Ранг: Экселист

Сообщений: 9185

Репутация: 2448 ±

Замечаний: 0% ±

Excel 2010

Цитата Serge_007, 01.02.2021 в 09:10, в сообщении № 14 ()

в делопроизводстве есть правило

тогда так

Код

=ДАТА(ЛЕВБ(ПРАВБ(B2;7);4);ПОИСК(ПСТР(B2;ПОИСК("от";B2)+7;2);"цнвеварпраяюнюлвгенктояек")/2;ПСТР(B2;ПОИСК("от";B2)+3;2))

Код

=--ПОДСТАВИТЬ(ЛЕВБ(ЗАМЕНИТЬ(B2;1;ПОИСК("от";B2)+2;);6)&ЛЕВБ(ПРАВБ(B2;8);5);"ая";"ай")

ЮMoney 41001841029809

Сообщение отредактировал Nic70y - Понедельник, 01.02.2021, 11:09

Ответить

Извлечь дату из текста в цифровом формате (Формулы/Formulas)

Страница 1 из 1
1

© 2010-2025 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!