Перенос значений учитывая месяцы - Мир MS Excel

Регистрация

Напомнить пароль

= Мир MS Excel/Перенос значений учитывая месяцы - Мир MS Excel

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Перенос значений учитывая месяцы (Формулы/Formulas)

Перенос значений учитывая месяцы

Дата: Суббота, 16.04.2022, 14:51 | Сообщение № 1

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

Добрый день , прошу еще раз помощи. Как мне перенести данные с листа "нормы" учитывая месяцы( столбцы переноса выделены голубым) В ячейка E18 будет выплывающий список по профессиям. Он должен быть связан с ячейкой F "нормы" ( в примере) .Т.е сначала данные в таблицу переносятся по столбцу январь (если в январе пусто , то значения не переносятся , далее февраль .....

К сообщению приложен файл: 8429624.xls (51.0 Kb)

Сообщение отредактировал GGR - Суббота, 16.04.2022, 15:03

Ответить

Дата: Суббота, 16.04.2022, 17:45 | Сообщение № 2

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4147

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

сложновато конечно, но работает

Код

=IFERROR(INDEX(нормы!H:H;SMALL(IF((нормы!$F$7:$F$18=$E$18)*(INDEX(нормы!$N$7:$Y$18;;MATCH(ROWS($A$38:A38)-1;MMULT(MMULT(COLUMN(A:L)^0;(нормы!$F$7:$F$18=$E$18)*(нормы!$N$7:$Y$18<>""));--(ROW($1:$12)<COLUMN(A:L)))))<>"");ROW(нормы!$F$7:$F$18));ROWS($A$38:A38)-LOOKUP(ROWS($A$38:A38)-1;MMULT(MMULT(COLUMN(A:L)^0;(нормы!$F$7:$F$18=$E$18)*(нормы!$N$7:$Y$18<>""));--(ROW($1:$12)<COLUMN(A:L))))));"")

К сообщению приложен файл: Example2644.xlsx (26.4 Kb)

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Сообщение отредактировал bmv98rus - Суббота, 16.04.2022, 18:09

Ответить

Дата: Суббота, 16.04.2022, 18:57 | Сообщение № 3

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

bmv98rus, спасибо за решение. Я вставила вашу формулу к себе в оригинал файла ,но к сожалению программа пишет : "Не удается ввести указанную формулу, поскольку имеет больше уровней сложности..." Массив проставила. Не понимаю, что я не так сделала? Подскажите пожалуйста, не поняла вот это выражение (СТОЛБЕЦ(A:L)^0. Если задать диапазон больше формула не работает в ваше файле.

Сообщение отредактировал GGR - Суббота, 16.04.2022, 19:37

Ответить

Дата: Суббота, 16.04.2022, 19:45 | Сообщение № 4

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4147

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

1 у вас файл xls и там есть ограничения, но чето я там перемудрил, все проще

Код

=IFERROR(INDEX(нормы!H:H;RIGHT(AGGREGATE(15;6;(COLUMN(нормы!$N$7:$Y$18)*1000+ROW(нормы!$N$7:$Y$18))/(нормы!$N$7:$Y$18<>"")/(нормы!$F$7:$F$18=$E$18);ROWS($A$38:A38));3));"")

К сообщению приложен файл: 4631286.xlsx (28.9 Kb)

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Дата: Суббота, 16.04.2022, 20:07 | Сообщение № 5

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

bmv98rus, у меня опять проблема. Ваша формула с Агрегатом не работает. У меня 2007. Не смогли бы вы мне дописать формулу?В файле " норма" проставила полный диапазон строк.

К сообщению приложен файл: 7820742.xlsx (32.6 Kb)

Ответить

Дата: Суббота, 16.04.2022, 20:12 | Сообщение № 6

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4147

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

Код

=IFERROR(INDEX(нормы!H:H;RIGHT(SMALL(IF((нормы!$N$7:$Y$18<>"")*(нормы!$F$7:$F$18=$E$18);COLUMN(нормы!$N$7:$Y$18)*1000+ROW(нормы!$N$7:$Y$18));ROWS($A$38:A38));3));"")

К сообщению приложен файл: 0417267.xlsx (31.6 Kb)

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Дата: Суббота, 16.04.2022, 20:31 | Сообщение № 7

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

bmv98rus, все отлично работает. Чтобы я до конца все поняла подскажите пожалуйста , что означает *1000?Искренне благодарю.

Ответить

Дата: Суббота, 16.04.2022, 20:55 | Сообщение № 8

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4147

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

Цитата GGR, 16.04.2022 в 20:31, в сообщении № 7 (

)

что означает *1000

умножение на тысячу :-)

все несложно , номер столбца умножается на 1000. Допустим это 15, будет 15000 к этому прибавляются номер строки , для первой в таблице будет 7
15007, далее будет 15009 , так как в восьмой строке января нет ююю .... . все числа берутся в порядке возрастания, то есть сперва пойдут все подходящие первого столбца, потом второго ...
взяв от полученного числа правые 3 символа получаем номер строки, из которой нужно взять значение. то есть 7, 9 ....
Если строк более 1000 то умножить надо на 10000 или 10^4 и взять 4 символа справа, а не 3.

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Дата: Суббота, 16.04.2022, 20:55 | Сообщение № 9

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

bmv98rus, Я очень извиняюсь. Просмотрела. Можно еще месяц добавить.Хотела сама, но попытка не увенчалась успехом.

Сообщение отредактировал GGR - Суббота, 16.04.2022, 21:19

Ответить

Дата: Суббота, 16.04.2022, 21:06 | Сообщение № 10

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4147

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

Ну я б ваще иначе чуток заносил данные, хотя это и не влияет на результат
а месяц это

Код

=DATE(;SMALL(IF((нормы!$N$7:$Y$18<>"")*(нормы!$F$7:$F$18=$E$18);COLUMN(нормы!$N$7:$Y$18)-COLUMN(M:M));ROWS($A$38:A38));1)

и формат

К сообщению приложен файл: Example2644_1.xlsx (33.1 Kb)

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Дата: Суббота, 16.04.2022, 21:16 | Сообщение № 11

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

bmv98rus, месяца сдвинуты+1. Как поправить?Формула тянет данные не только от E18 но и последующие значения, которые не подходят под данную профессию.

Сообщение отредактировал GGR - Суббота, 16.04.2022, 21:19

Ответить

Дата: Суббота, 16.04.2022, 21:26 | Сообщение № 12

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4147

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

Цитата GGR, 16.04.2022 в 21:16, в сообщении № 11 (

)

месяца сдвинуты+1

где?

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Дата: Суббота, 16.04.2022, 21:31 | Сообщение № 13

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

bmv98rus, В листе карточка , столбец S. Начинаются с февраля. По данным январь

Ответить

Дата: Суббота, 16.04.2022, 21:37 | Сообщение № 14

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4147

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

не наблюдаю.

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Дата: Суббота, 16.04.2022, 22:26 | Сообщение № 15

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

bmv98rus, посмотрите пожалуйста , месяц не так подтягивает. Файл вложен

К сообщению приложен файл: _2022.xls (127.0 Kb)

Сообщение отредактировал GGR - Суббота, 16.04.2022, 22:26

Ответить

Дата: Суббота, 16.04.2022, 22:57 | Сообщение № 16

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4147

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

Код

=DATE(;SMALL(IF((нормы!$O$7:$Z$100<>"")*(нормы!$G$7:$G$100=$D$18);COLUMN(нормы!$O$7:$Z$100)-COLUMN(N:N));ROWS($A$38:A38));1)

или

Код

=DATE(;SMALL(IF((нормы!$O$7:$Z$100<>"")*(нормы!$G$7:$G$100=$D$18);COLUMN(A:L));ROWS($A$38:A38));1)

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Дата: Суббота, 16.04.2022, 23:19 | Сообщение № 17

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 130

Репутация: 0 ±

Замечаний: 20% ±

Excel 2007

bmv98rus, 2 вариант подошел лучше. Благодарю за помощь.

Ответить

Перенос значений учитывая месяцы (Формулы/Formulas)

Страница 1 из 1
1

© 2010-2025 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!