Подставить связанные данные с другого листа

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подставить связанные данные с другого листа (Формулы/Formulas)

BBC

Дата: Воскресенье, 31.03.2024, 23:47 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 29

Репутация: 0 ±

Замечаний: 0% ±

Excel LTSC

Доброго времени суток. Есть бланк письма с таблицей. В другом листе данные вся информация по сотрудникам. Как сделать,чтобы выбирая в таблице письма нескольких сотрудников, в соседние ячейки копировались их данные с второго листа. Причем в ячейке С нужно объединить дату и номер приказа. Функцией СЦЕПИТЬ у меня ничего не вышло. Выпадающий список сотрудников в столбце В я сделал.

К сообщению приложен файл: blank_1.xlsx (18.9 Kb)

Ответить

Gustav

Дата: Понедельник, 01.04.2024, 01:29 | Сообщение № 2

Группа: Друзья

Ранг: Участник клуба

Сообщений: 2748

Репутация: 1137 ±

Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1

Цитата BBC, 31.03.2024 в 23:47, в сообщении № 1 (

)

Функцией СЦЕПИТЬ у меня ничего не вышло

Вы имеете в виду, что вместо даты 04.06.2018 сцепилось "непонятное" число 43255 ? Ну, это нормально. Чтобы дата отобразилась в привычном виде, её нужно подать на "сцепку", отформатировав функцией ТЕКСТ:

Код

=СЦЕПИТЬ(ТЕКСТ(C3;"ДД.ММ.ГГГГ");" ";D3)

Тогда формула для ячейки C7 листа "Письмо" может быть такой:

Код

=ЕСНД(СЦЕПИТЬ(ВПР(B7; данные!$B$3:$E$19; 3;); СИМВОЛ(10); ТЕКСТ(ВПР(B7; данные!$B$3:$E$19; 2;); "ДД.ММ.ГГГГ"));"")

или такой, если сначала должна идти дата:

Код

=ЕСНД(СЦЕПИТЬ(ТЕКСТ(ВПР(B7; данные!$B$3:$E$19; 2;); "ДД.ММ.ГГГГ"); СИМВОЛ(10); ВПР(B7; данные!$B$3:$E$19; 3;));"")

И, наконец, формула для ячейки D7 листа "Письмо":

Код

=ЕСНД(ВПР(B7; данные!$B$3:$E$19; 4;); "")

МОИ: Ник, Tip box: 41001663842605

Сообщение отредактировал Gustav - Понедельник, 01.04.2024, 01:52

Ответить

DrMini

Дата: Понедельник, 01.04.2024, 06:00 | Сообщение № 3

Группа: Друзья

Ранг: Старожил

Сообщений: 1655

Репутация: 210 ±

Замечаний: 0% ±

Excel LTSC 2024 RUS

Здравствуйте BBC,
Просто как вариант.

Код

=ОБЪЕДИНИТЬ(СИМВОЛ(10);;ИНДЕКС(данные!$D$3:$D$19;ПОИСКПОЗ(B7;данные!$B$3:$B$19;));ТЕКСТ(ИНДЕКС(данные!$C$3:$C$19;ПОИСКПОЗ(B7;данные!$B$3:$B$19;));"ДД.ММ.ГГГГ"))

Код

=ЕСНД(ИНДЕКС(данные!$E$3:$E$19;ПОИСКПОЗ(B7;данные!$B$3:$B$19;));"")

К сообщению приложен файл: 0760049.xlsx (14.1 Kb)

Ответить

Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подставить связанные данные с другого листа (Формулы/Formulas)

Страница 1 из 1
1