let
    PowerTrim = (text as text) => let
        step1= Text.SplitAny(text, " "&Character.FromNumber(160)),
        step2 = List.Select(step1, each _ <> ""),
        resut = Text.Combine(step2, " ")
    in
        resut,
    CombineRows = (tbl as table) as table => let
        step1 = Table.Transpose(Table.TransformColumns(tbl,{},each try Text.From(_) otherwise _)),
        step2 = Table.CombineColumns(step1 ,Table.ColumnNames(step1),Combiner.CombineTextByDelimiter(" ",QuoteStyle.None),"Merged"),
        resut = Table.Transpose(Table.PromoteHeaders(step2))
    in
        resut,
    GetTable = (tbl as table) as table => let
        FirstCol = Table.ColumnNames(tbl ){0},
        step0 = Table.TransformColumnTypes(Table.ReplaceValue(tbl,"",null,Replacer.ReplaceValue,{FirstCol}),{{FirstCol, type text}}, "ru-RU"),
        step1 = Table.SplitColumn(step0,"Столбец1",Splitter.SplitTextByEachDelimiter({"."," "," "},QuoteStyle.None),{FirstCol}),
        step2 = Table.FillDown(step1,{"Столбец1"}),
        step3 = Table.Group(step2, {"Столбец1"}, {{"tbl", each CombineRows(_), type table}}),
        step4 = Table.ExpandTableColumn(step3, "tbl", Table.ColumnNames(step3[tbl]{0})),
        step5 = Table.FromRows(Table.ToRows(step4),Table.ColumnNames(tbl)),
        resut = Table.TransformColumns(step5,{},PowerTrim)
    in
        resut,
    Table1 = GetTable(Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content]),
    Table2 = GetTable(Excel.CurrentWorkbook(){[Name="Таблица2"]}[Content]),
    Join = Table.NestedJoin(Table1,List.Range(Table.ColumnNames(Table1),0,2),Table2,List.Range(Table.ColumnNames(Table2),0,2),"NewColumn",JoinKind.FullOuter),
    Expand = Table.ExpandTableColumn(Join, "NewColumn", Table.ColumnNames(Table2),List.Transform(Table.ColumnNames(Table2),each _&".1")),
    result = Table.TransformColumns(Expand,{},each try Number.From(_) otherwise _)
in
    result

let
    Источник =
        Table.Group(
            Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
            {"FIO"},
            {
                {
                    "МИН(timeStart)",
                    each Time.From(List.Min([timeStart])),
                    type time
                },
                {
                    "МАКС(timeEnd)",
                    each Time.From(List.Max([timeEnd])),
                    type time
                },
                {
                    "МАКС(timeEnd)-МИН(timeStart)",
                    each Time.From(List.Max([timeEnd])-List.Min([timeStart])),
                    type time
                }
            }
        )
in
    Источник

let
    Папка = Folder.Files(
                Excel.CurrentWorkbook(){[Name="folder"]}[Content][Column1]{0}
            )[[Folder Path],[Name],[Extension],[Content]],
    Файлы = Table.SelectRows(
                Папка,
                each
                    Text.StartsWith(_[Extension], ".xls") and
                    not Text.StartsWith(_[Name], "~")
            ),
    Книги = Table.CombineColumns(
                Table.SelectColumns(
                    Table.AddColumn(
                        Файлы,
                        "Workbook",  
                        each
                            Table.SelectRows(
                    Excel.Workbook([Content]),
                    each
                    _[Kind] = "Sheet"
                            )
                    ),
                    {"Name", "Folder Path", "Workbook"}
                ),
                {"Folder Path", "Name"},
                Combiner.CombineTextByDelimiter(
                    "",
                    QuoteStyle.None
                ),
                "Файл"
            ),
    Листы = Table.TransformColumns(
                Table.ExpandTableColumn(
                    Книги,
                    "Workbook",
                    {"Name", "Data"},
                    {"Лист","Data"}
                ),
                {"Data", Table.PromoteHeaders}
            ),
    Столбцы = Table.Distinct(
                  Table.ExpandListColumn(
                      Table.AddColumn(
                          Листы,
                          "",
                          each
                    Table.ColumnNames([Data])
                      ),
                      ""
                  ),
                  {""}
              )[#""],
    Таблица = Table.ExpandTableColumn(
                  Листы,
                  "Data",
                  Столбцы
              )
in
    Таблица