Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Как изменить разбиение слоев по толщинам? - Мир MS Excel

Регистрация · Логин: · Пароль: · · Забыли пароль?
  • Страница 1 из 1
  • 1
Модератор форума: _Boroda_, Manyasha, SLAVICK, китин  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Как изменить разбиение слоев по толщинам? (Формулы/Formulas)
Как изменить разбиение слоев по толщинам?
Юрий_Нд Дата: Вторник, 04.09.2018, 00:09 | Сообщение № 1
Группа: Проверенные
Ранг: Обитатель
Сообщений: 294
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Доброй ночи Всем.
Есть следующая задача.
Некоторый плоский материал состоит из множества слоев.
В табличном виде задается порядковый номер очередного слоя и его толщина.
Пример этого в таблице 1.
Задача:
В случае, если толщина очередного слоя превышает 0,2, необходимо разбить слой на толщины с шагом 0,2. Ну и конечно же должна быть обозначена конечная толщина очередного слоя.
Пример такого, изменённого разбиения показан в таблице 2.
Как это делать в ВБА я знаю.
Но хотелось бы всё это сделать с помощью обычных формул.
Возможно ли это?
Спасибо ___________ Юрий.
К сообщению приложен файл: -2.xlsx(9.0 Kb)
 
Ответить
СообщениеДоброй ночи Всем.
Есть следующая задача.
Некоторый плоский материал состоит из множества слоев.
В табличном виде задается порядковый номер очередного слоя и его толщина.
Пример этого в таблице 1.
Задача:
В случае, если толщина очередного слоя превышает 0,2, необходимо разбить слой на толщины с шагом 0,2. Ну и конечно же должна быть обозначена конечная толщина очередного слоя.
Пример такого, изменённого разбиения показан в таблице 2.
Как это делать в ВБА я знаю.
Но хотелось бы всё это сделать с помощью обычных формул.
Возможно ли это?
Спасибо ___________ Юрий.

Автор - Юрий_Нд
Дата добавления - 04.09.2018 в 00:09
Nic70y Дата: Вторник, 04.09.2018, 08:41 | Сообщение № 2
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4888
Репутация: 1060 ±
Замечаний: 0% ±

Excel 2013
вариант с доп.столбцами
К сообщению приложен файл: 9947027.xlsx(10.3 Kb)


ЯД(poison) 41001841029809
+7 978 049 98 74 (мтс)
 
Ответить
Сообщениевариант с доп.столбцами

Автор - Nic70y
Дата добавления - 04.09.2018 в 08:41
Светлый Дата: Вторник, 04.09.2018, 15:33 | Сообщение № 3
Группа: Проверенные
Ранг: Ветеран
Сообщений: 707
Репутация: 186 ±
Замечаний: 0% ±

Excel 2010
Формула массива (Ctrl+Shift+Enter) без оптимизации:
Код
=ЕСЛИ(СМЕЩ(D$6;СУММ(--(ОКРУГЛ(ОСТАТ(Ч(+I$5:I5)*5;1);9)>0));)*5<1;СМЕЩ(D$6;СУММ(--(ОКРУГЛ(ОСТАТ(Ч(+I$5:I5)*5;1);9)>0)););ЕСЛИ(I5*5<1;1/5;МИН(I5+1/5;СМЕЩ(D$6;СУММ(--(ОКРУГЛ(ОСТАТ(Ч(+I$5:I5)*5;1);9)>0));))))

*Сократил формулу до 86 символов. Так и хочется в МШ запустить.
**Формула работает не всегда. Использовать нельзя.


Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Вторник, 04.09.2018, 20:00
 
Ответить
СообщениеФормула массива (Ctrl+Shift+Enter) без оптимизации:
Код
=ЕСЛИ(СМЕЩ(D$6;СУММ(--(ОКРУГЛ(ОСТАТ(Ч(+I$5:I5)*5;1);9)>0));)*5<1;СМЕЩ(D$6;СУММ(--(ОКРУГЛ(ОСТАТ(Ч(+I$5:I5)*5;1);9)>0)););ЕСЛИ(I5*5<1;1/5;МИН(I5+1/5;СМЕЩ(D$6;СУММ(--(ОКРУГЛ(ОСТАТ(Ч(+I$5:I5)*5;1);9)>0));))))

*Сократил формулу до 86 символов. Так и хочется в МШ запустить.
**Формула работает не всегда. Использовать нельзя.

Автор - Светлый
Дата добавления - 04.09.2018 в 15:33
Nic70y Дата: Вторник, 04.09.2018, 20:36 | Сообщение № 4
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4888
Репутация: 1060 ±
Замечаний: 0% ±

Excel 2013
без доп.столбцов, но с махлежом в №
H6
Код
=1,001+ОКРУГЛВВЕРХ(D6/0,2;)/1000000
H7 и ниже
Код
=1+H6+ЕСЛИ(ОКРУГЛВВЕРХ(ВПР(ОКРУГЛ(ОСТАТ(H6;1)*1000;);C$6:D$10;2)/0,2;)>ОКРУГЛ(ОСТАТ(ОСТАТ(H6;1)*1000;1)*1000;);0,000001;0,001)
I6 и ниже
Код
=МИН(ВПР(ОСТАТ(H6;1)*1000;C$6:D$10;2);ОКРУГЛ(ОСТАТ(ОСТАТ(H6;1)*1000;1)*1000;)*0,2)

работает до 999 строк, 999 слоев исходной таблицы
К сообщению приложен файл: -2-1-.xlsx(10.3 Kb)


ЯД(poison) 41001841029809
+7 978 049 98 74 (мтс)


Сообщение отредактировал Nic70y - Вторник, 04.09.2018, 20:54
 
Ответить
Сообщениебез доп.столбцов, но с махлежом в №
H6
Код
=1,001+ОКРУГЛВВЕРХ(D6/0,2;)/1000000
H7 и ниже
Код
=1+H6+ЕСЛИ(ОКРУГЛВВЕРХ(ВПР(ОКРУГЛ(ОСТАТ(H6;1)*1000;);C$6:D$10;2)/0,2;)>ОКРУГЛ(ОСТАТ(ОСТАТ(H6;1)*1000;1)*1000;);0,000001;0,001)
I6 и ниже
Код
=МИН(ВПР(ОСТАТ(H6;1)*1000;C$6:D$10;2);ОКРУГЛ(ОСТАТ(ОСТАТ(H6;1)*1000;1)*1000;)*0,2)

работает до 999 строк, 999 слоев исходной таблицы

Автор - Nic70y
Дата добавления - 04.09.2018 в 20:36
Светлый Дата: Вторник, 04.09.2018, 21:10 | Сообщение № 5
Группа: Проверенные
Ранг: Ветеран
Сообщений: 707
Репутация: 186 ±
Замечаний: 0% ±

Excel 2010
работает до 999 строк, 999 слоев

Как и моя, эта формула тоже не работает. Неправильно, если в первой строке больше 0,2 и неправильно, если подряд два слоя больше 0,2.


Программировать проще, чем писать стихи.
 
Ответить
Сообщение
работает до 999 строк, 999 слоев

Как и моя, эта формула тоже не работает. Неправильно, если в первой строке больше 0,2 и неправильно, если подряд два слоя больше 0,2.

Автор - Светлый
Дата добавления - 04.09.2018 в 21:10
Светлый Дата: Четверг, 06.09.2018, 07:27 | Сообщение № 6
Группа: Проверенные
Ранг: Ветеран
Сообщений: 707
Репутация: 186 ±
Замечаний: 0% ±

Excel 2010
Докрутил до рабочего состояния массивную формулу:
Код
=ЕСЛИ(ПОИСКПОЗ(Ч(H5);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%)))=ПОИСКПОЗ(Ч(H6);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%)));(ПОИСКПОЗ(Ч(H5);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%)))=ПОИСКПОЗ(Ч(H4);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%))))*(H6>1)*Ч(I5)+1/5;ИНДЕКС(D$6:D$26;ПОИСКПОЗ(Ч(H5);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%)))))

Сейчас правильно первая строка работает, две подряд больше 0,2 и исходные значения, кратные 0,2
К сообщению приложен файл: -2-3.xlsx(11.4 Kb)


Программировать проще, чем писать стихи.
 
Ответить
СообщениеДокрутил до рабочего состояния массивную формулу:
Код
=ЕСЛИ(ПОИСКПОЗ(Ч(H5);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%)))=ПОИСКПОЗ(Ч(H6);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%)));(ПОИСКПОЗ(Ч(H5);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%)))=ПОИСКПОЗ(Ч(H4);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%))))*(H6>1)*Ч(I5)+1/5;ИНДЕКС(D$6:D$26;ПОИСКПОЗ(Ч(H5);МУМНОЖ(--(C$6:C$26>ТРАНСП(C$6:C$26));ОТБР(D$6:D$26*5+1-1%%)))))

Сейчас правильно первая строка работает, две подряд больше 0,2 и исходные значения, кратные 0,2

Автор - Светлый
Дата добавления - 06.09.2018 в 07:27
Светлый Дата: Четверг, 06.09.2018, 11:51 | Сообщение № 7
Группа: Проверенные
Ранг: Ветеран
Сообщений: 707
Репутация: 186 ±
Замечаний: 0% ±

Excel 2010
Цитата Юрий_Нд, 04.09.2018 в 00:09, в сообщении № 1 ()
В случае, если толщина очередного слоя превышает 0,2, необходимо разбить слой на толщины с шагом 0,2.

В моём понимании немного не увязывается логика разбиения толстых слоёв. Если для дальнейших расчётов слои не должны превышать 0,2 , их надо разбивать на 0,2+0,2+0,2+остаток, а не 0,2+0,4+0,6+полная толщина. И формула разбивки получится проще.
*Ячейки J6 и K6
Код
=МИН(1/5;ЕСЛИ(СУММЕСЛИ(СМЕЩ(D$6;;;C$6:C$16);">0")>СУММ(J$5:J5);СУММЕСЛИ(СМЕЩ(D$6;;;C$6:C$16);">0")-СУММ(J$5:J5)))

Код
=МИН(1/5;--ТЕКСТ(ОКРУГЛ(СУММЕСЛИ(СМЕЩ(D$6;;;C$6:C$16);">0")-СУММ(K$5:K5);2);"0,00;9;9"))


Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Четверг, 06.09.2018, 13:48
 
Ответить
Сообщение
Цитата Юрий_Нд, 04.09.2018 в 00:09, в сообщении № 1 ()
В случае, если толщина очередного слоя превышает 0,2, необходимо разбить слой на толщины с шагом 0,2.

В моём понимании немного не увязывается логика разбиения толстых слоёв. Если для дальнейших расчётов слои не должны превышать 0,2 , их надо разбивать на 0,2+0,2+0,2+остаток, а не 0,2+0,4+0,6+полная толщина. И формула разбивки получится проще.
*Ячейки J6 и K6
Код
=МИН(1/5;ЕСЛИ(СУММЕСЛИ(СМЕЩ(D$6;;;C$6:C$16);">0")>СУММ(J$5:J5);СУММЕСЛИ(СМЕЩ(D$6;;;C$6:C$16);">0")-СУММ(J$5:J5)))

Код
=МИН(1/5;--ТЕКСТ(ОКРУГЛ(СУММЕСЛИ(СМЕЩ(D$6;;;C$6:C$16);">0")-СУММ(K$5:K5);2);"0,00;9;9"))

Автор - Светлый
Дата добавления - 06.09.2018 в 11:51
Nic70y Дата: Четверг, 06.09.2018, 13:40 | Сообщение № 8
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4888
Репутация: 1060 ±
Замечаний: 0% ±

Excel 2013
ну, да в №4 накосячил,
раскосячил (наверное)
4999 - строк, 99 слоев
Код
=ЕСЛИ(H6="";"";ЕСЛИ(ОКРУГЛВНИЗ(ОСТАТ(H6;1)*10000;)+1>МАКС(C$6:C$10);"";1+ЕСЛИ(ОКРУГЛВВЕРХ(ИНДЕКС(D$6:D$10;ОКРУГЛВНИЗ(ОСТАТ(H6;1)*10000;))/0,2;)=--ПРАВБ(ОКРУГЛ(H6;6);2);0,000101+ОКРУГЛВНИЗ(H6;4);0,000001+H6)))
Код
=ЕСЛИ(H6="";"";МИН(ПРАВБ(ОКРУГЛ(H6;6);2)*0,2;ИНДЕКС(D$6:D$10;ОКРУГЛВНИЗ(ОСТАТ(H6;1)*10000;))))
К сообщению приложен файл: -2-2-.xlsx(10.2 Kb)


ЯД(poison) 41001841029809
+7 978 049 98 74 (мтс)
 
Ответить
Сообщениену, да в №4 накосячил,
раскосячил (наверное)
4999 - строк, 99 слоев
Код
=ЕСЛИ(H6="";"";ЕСЛИ(ОКРУГЛВНИЗ(ОСТАТ(H6;1)*10000;)+1>МАКС(C$6:C$10);"";1+ЕСЛИ(ОКРУГЛВВЕРХ(ИНДЕКС(D$6:D$10;ОКРУГЛВНИЗ(ОСТАТ(H6;1)*10000;))/0,2;)=--ПРАВБ(ОКРУГЛ(H6;6);2);0,000101+ОКРУГЛВНИЗ(H6;4);0,000001+H6)))
Код
=ЕСЛИ(H6="";"";МИН(ПРАВБ(ОКРУГЛ(H6;6);2)*0,2;ИНДЕКС(D$6:D$10;ОКРУГЛВНИЗ(ОСТАТ(H6;1)*10000;))))

Автор - Nic70y
Дата добавления - 06.09.2018 в 13:40
Светлый Дата: Четверг, 06.09.2018, 14:58 | Сообщение № 9
Группа: Проверенные
Ранг: Ветеран
Сообщений: 707
Репутация: 186 ±
Замечаний: 0% ±

Excel 2010
99 слоев

На 10 слое вместо 2,0 показывает 2,2 из-за функции ПРАВБ
Неизвестно, сколько слоёв потребуется. Не думаю, что так много.
[offtop]Я не зануда :)


Программировать проще, чем писать стихи.
 
Ответить
Сообщение
99 слоев

На 10 слое вместо 2,0 показывает 2,2 из-за функции ПРАВБ
Неизвестно, сколько слоёв потребуется. Не думаю, что так много.
[offtop]Я не зануда :)

Автор - Светлый
Дата добавления - 06.09.2018 в 14:58
Юрий_Нд Дата: Четверг, 06.09.2018, 19:25 | Сообщение № 10
Группа: Проверенные
Ранг: Обитатель
Сообщений: 294
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Цитата Светлый, 06.09.2018 в 11:51, в сообщении № 7 ()
В моём понимании немного не увязывается логика разбиения толстых слоёв. Если для дальнейших расчётов слои не должны превышать 0,2 , их надо разбивать на 0,2+0,2+0,2+остаток,

Именно так и нужно делать.
Хотя, товарищи, должен сказать, что не думал, что формула окажется такой сложной.
Думаю, что нужно всё-таки подключать ВБА.
Потому, что там нужно ещё соблюсти несколько нюансов.
Постараюсь показать всю задачу в ближайшее время.
В любом случае, очень благодарю Вас за активное участие в решении моих проблем.

п.с. Да и с количеством слоев. Вроде бы больше 10 это достаточное экзотическая ситуация, но всё-таки не хотелось бы ограничивать.


Сообщение отредактировал Юрий_Нд - Четверг, 06.09.2018, 19:43
 
Ответить
Сообщение
Цитата Светлый, 06.09.2018 в 11:51, в сообщении № 7 ()
В моём понимании немного не увязывается логика разбиения толстых слоёв. Если для дальнейших расчётов слои не должны превышать 0,2 , их надо разбивать на 0,2+0,2+0,2+остаток,

Именно так и нужно делать.
Хотя, товарищи, должен сказать, что не думал, что формула окажется такой сложной.
Думаю, что нужно всё-таки подключать ВБА.
Потому, что там нужно ещё соблюсти несколько нюансов.
Постараюсь показать всю задачу в ближайшее время.
В любом случае, очень благодарю Вас за активное участие в решении моих проблем.

п.с. Да и с количеством слоев. Вроде бы больше 10 это достаточное экзотическая ситуация, но всё-таки не хотелось бы ограничивать.

Автор - Юрий_Нд
Дата добавления - 06.09.2018 в 19:25
Юрий_Нд Дата: Пятница, 07.09.2018, 10:39 | Сообщение № 11
Группа: Проверенные
Ранг: Обитатель
Сообщений: 294
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Цитата Светлый, 04.09.2018 в 15:33, в сообщении № 3 ()
Так и хочется в МШ запустить.

Очень интересно, что Вы имели в виду.
 
Ответить
Сообщение
Цитата Светлый, 04.09.2018 в 15:33, в сообщении № 3 ()
Так и хочется в МШ запустить.

Очень интересно, что Вы имели в виду.

Автор - Юрий_Нд
Дата добавления - 07.09.2018 в 10:39
китин Дата: Пятница, 07.09.2018, 11:44 | Сообщение № 12
Группа: Модераторы
Ранг: Участник клуба
Сообщений: 5105
Репутация: 810 ±
Замечаний: 0% ±

Excel 2007;Excel 2010
Очень интересно, что Вы имели в виду.

МШ-мозговой штурм. есть такой раздел на этом форуме. почитайте. оч. интересно


Не судите строго:я пытаюсь научиться
ЯД 41001877306852/WM R249698041931; Z239672726538
 
Ответить
Сообщение
Очень интересно, что Вы имели в виду.

МШ-мозговой штурм. есть такой раздел на этом форуме. почитайте. оч. интересно

Автор - китин
Дата добавления - 07.09.2018 в 11:44
Юрий_Нд Дата: Пятница, 07.09.2018, 14:16 | Сообщение № 13
Группа: Проверенные
Ранг: Обитатель
Сообщений: 294
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Ещё раз тысячу извинений.
Всё-таки решение поставленной мною задачи с помощью стандартных формул Excel получается очень непрозрачным, то есть трудный для понимания, а следовательно для редактирования, допустим через год.
Поэтому обращаюсь ко Всем с просьбой решить данную задачу с помощью средств ВБА.
Аналогичная тема существует в разделе Excel vbа, но возможно, если модератор сочтет нужным не плодить темы, тогда я прошу ответить в этом разделе.
Да вот еще.
В исходном файле разбиение 2 слоя идёт как 0.2, 0.4 и 0.51. Это неверно. Должно быть всё как в приложенном здесь файле Excel,
или
слой номер 2 имеет толщину больше чем 0.2, то есть его толщина 0.51. Следовательно этот слой делится на толщины кратные 0.2. То есть, сначала толщина 0.2, затем толщина ещё раз 0.2, и наконец остаток толщины 0.11.
В итоге получаем что толщина слоя 0.51 разбивается на три слоя 0.2 + 0.2 + 0.11.
К сообщению приложен файл: 5130986.xlsx(9.3 Kb)


Сообщение отредактировал Юрий_Нд - Пятница, 07.09.2018, 14:59
 
Ответить
СообщениеЕщё раз тысячу извинений.
Всё-таки решение поставленной мною задачи с помощью стандартных формул Excel получается очень непрозрачным, то есть трудный для понимания, а следовательно для редактирования, допустим через год.
Поэтому обращаюсь ко Всем с просьбой решить данную задачу с помощью средств ВБА.
Аналогичная тема существует в разделе Excel vbа, но возможно, если модератор сочтет нужным не плодить темы, тогда я прошу ответить в этом разделе.
Да вот еще.
В исходном файле разбиение 2 слоя идёт как 0.2, 0.4 и 0.51. Это неверно. Должно быть всё как в приложенном здесь файле Excel,
или
слой номер 2 имеет толщину больше чем 0.2, то есть его толщина 0.51. Следовательно этот слой делится на толщины кратные 0.2. То есть, сначала толщина 0.2, затем толщина ещё раз 0.2, и наконец остаток толщины 0.11.
В итоге получаем что толщина слоя 0.51 разбивается на три слоя 0.2 + 0.2 + 0.11.

Автор - Юрий_Нд
Дата добавления - 07.09.2018 в 14:16
Светлый Дата: Пятница, 07.09.2018, 20:00 | Сообщение № 14
Группа: Проверенные
Ранг: Ветеран
Сообщений: 707
Репутация: 186 ±
Замечаний: 0% ±

Excel 2010
Вышеприведённая моя формула для этого файла (массивная) вполне работоспособна:
Код
=МИН(1/5;--ТЕКСТ(ОКРУГЛ(СУММЕСЛИ(СМЕЩ(E$6;;;C$6:C$10);">0")-СУММ(K$5:K5);2);"0.00;9;9"))


Программировать проще, чем писать стихи.
 
Ответить
СообщениеВышеприведённая моя формула для этого файла (массивная) вполне работоспособна:
Код
=МИН(1/5;--ТЕКСТ(ОКРУГЛ(СУММЕСЛИ(СМЕЩ(E$6;;;C$6:C$10);">0")-СУММ(K$5:K5);2);"0.00;9;9"))

Автор - Светлый
Дата добавления - 07.09.2018 в 20:00
Юрий_Нд Дата: Суббота, 08.09.2018, 01:06 | Сообщение № 15
Группа: Проверенные
Ранг: Обитатель
Сообщений: 294
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Светлый, Вы не могли бы показать, как Ваша формула работает в файле Excel?
 
Ответить
СообщениеСветлый, Вы не могли бы показать, как Ваша формула работает в файле Excel?

Автор - Юрий_Нд
Дата добавления - 08.09.2018 в 01:06
krosav4ig Дата: Суббота, 08.09.2018, 01:21 | Сообщение № 16
Группа: Друзья
Ранг: Старожил
Сообщений: 1698
Репутация: 699 ±
Замечаний: 0% ±

Excel 2007,2010,2013
для файла из 13 поста
Код
=ЕСЛИ(СТРОКА(I1)>СУММ(ОКРВВЕРХ(E$6:E$10;0,2)/0,2);"";СТРОКА(I1))
Назв.
Код
=ЕСЛИ(I6<"";ПРОСМОТР(СТРОКА(J1);МУМНОЖ(ЕСЛИ(Ч(+C$5:C$10)>=ТРАНСП(C$5:C$10);ТРАНСП(ОКРВВЕРХ(E$5:E$10;0,2)/0,2););СТРОКА(C$5:C$10)^0)+1;D$6:D$7);"")
Ти
Код
=ЕСЛИ(I6<"";--ТЕКСТ(ЕСЛИ(J6=J7;0,2;ОСТАТ(ВПР(J6;D$5:E$10;2;)/1%;20)%);"[=0]\0\,2");"")
К сообщению приложен файл: 1909139.xlsx(9.5 Kb)


(_)Õvõ(_)
 
Ответить
Сообщениедля файла из 13 поста
Код
=ЕСЛИ(СТРОКА(I1)>СУММ(ОКРВВЕРХ(E$6:E$10;0,2)/0,2);"";СТРОКА(I1))
Назв.
Код
=ЕСЛИ(I6<"";ПРОСМОТР(СТРОКА(J1);МУМНОЖ(ЕСЛИ(Ч(+C$5:C$10)>=ТРАНСП(C$5:C$10);ТРАНСП(ОКРВВЕРХ(E$5:E$10;0,2)/0,2););СТРОКА(C$5:C$10)^0)+1;D$6:D$7);"")
Ти
Код
=ЕСЛИ(I6<"";--ТЕКСТ(ЕСЛИ(J6=J7;0,2;ОСТАТ(ВПР(J6;D$5:E$10;2;)/1%;20)%);"[=0]\0\,2");"")

Автор - krosav4ig
Дата добавления - 08.09.2018 в 01:21
Светлый Дата: Суббота, 08.09.2018, 08:56 | Сообщение № 17
Группа: Проверенные
Ранг: Ветеран
Сообщений: 707
Репутация: 186 ±
Замечаний: 0% ±

Excel 2010
как Ваша формула работает в файле Excel

Формула берёт наименьшее значение из 0,2 и нескольких положительных разниц между последовательными суммами исходных толщин и уже занесённых в таблицу толщин. Если слой толстый, то 0,2 будет меньше его остатка - выбираем 0,2 до тех пор, пока остаток не станет меньше 0,2.
Как-то заумно получилось.
По-другому:
Находим суммы первых одного, двух, трёх и т.д. элементов исходных данных. Из них вычитаем сумму толщин уже занесённых в результат слоёв. Оставляем только положительные значения. Находим из них и значения 0,2 минимальное значение.
К сообщению приложен файл: 5130986-1.xlsx(9.7 Kb)


Программировать проще, чем писать стихи.
 
Ответить
Сообщение
как Ваша формула работает в файле Excel

Формула берёт наименьшее значение из 0,2 и нескольких положительных разниц между последовательными суммами исходных толщин и уже занесённых в таблицу толщин. Если слой толстый, то 0,2 будет меньше его остатка - выбираем 0,2 до тех пор, пока остаток не станет меньше 0,2.
Как-то заумно получилось.
По-другому:
Находим суммы первых одного, двух, трёх и т.д. элементов исходных данных. Из них вычитаем сумму толщин уже занесённых в результат слоёв. Оставляем только положительные значения. Находим из них и значения 0,2 минимальное значение.

Автор - Светлый
Дата добавления - 08.09.2018 в 08:56
Юрий_Нд Дата: Суббота, 08.09.2018, 11:38 | Сообщение № 18
Группа: Проверенные
Ранг: Обитатель
Сообщений: 294
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Доброго дня всем.
Светлый, при попытке "разрешить редактирование" Вашего файла, как я понимаю, формулы перестают работать.
Это можно как-то объяснить?
Красавчик, а Ваша-моя таблица замечательно работает.
Спасибо Всем.
 
Ответить
СообщениеДоброго дня всем.
Светлый, при попытке "разрешить редактирование" Вашего файла, как я понимаю, формулы перестают работать.
Это можно как-то объяснить?
Красавчик, а Ваша-моя таблица замечательно работает.
Спасибо Всем.

Автор - Юрий_Нд
Дата добавления - 08.09.2018 в 11:38
krosav4ig Дата: Суббота, 08.09.2018, 12:54 | Сообщение № 19
Группа: Друзья
Ранг: Старожил
Сообщений: 1698
Репутация: 699 ±
Замечаний: 0% ±

Excel 2007,2010,2013
Светлый, при попытке "разрешить редактирование" Вашего файла, как я понимаю, формулы перестают работать.

Замените в формуле точку на запятую (это десятичный разделитель, в разных локалях может отличаться)


(_)Õvõ(_)
 
Ответить
Сообщение
Светлый, при попытке "разрешить редактирование" Вашего файла, как я понимаю, формулы перестают работать.

Замените в формуле точку на запятую (это десятичный разделитель, в разных локалях может отличаться)

Автор - krosav4ig
Дата добавления - 08.09.2018 в 12:54
Светлый Дата: Суббота, 08.09.2018, 14:35 | Сообщение № 20
Группа: Проверенные
Ранг: Ветеран
Сообщений: 707
Репутация: 186 ±
Замечаний: 0% ±

Excel 2010
формулы перестают работать.

Так при любом десятичном разделителе будет работать:
Код
=МИН(1/5;--ТЕКСТ(ОКРУГЛ(СУММЕСЛИ(СМЕЩ(E$6;;;C$6:C$26);">0")-СУММ(K$5:K5);2);ЛЕВБ(1%;3)&"0;9;9"))


Программировать проще, чем писать стихи.
 
Ответить
Сообщение
формулы перестают работать.

Так при любом десятичном разделителе будет работать:
Код
=МИН(1/5;--ТЕКСТ(ОКРУГЛ(СУММЕСЛИ(СМЕЩ(E$6;;;C$6:C$26);">0")-СУММ(K$5:K5);2);ЛЕВБ(1%;3)&"0;9;9"))

Автор - Светлый
Дата добавления - 08.09.2018 в 14:35
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Как изменить разбиение слоев по толщинам? (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс цитирования
© 2010-2018 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!