Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Формула не выдает результат при записи месяца в 4 буквы - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Формула не выдает результат при записи месяца в 4 буквы (Формулы/Formulas)
Формула не выдает результат при записи месяца в 4 буквы
SergVrn Дата: Суббота, 03.11.2018, 05:15 | Сообщение № 1
Группа: Пользователи
Ранг: Участник
Сообщений: 87
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Здравствуйте.
У меня такой вопрос:

Есть формула определяющая - сколько дней осталось до определенной даты, или же сколько дней прошло.

Формула меняет месяцы, в соответствии со списком - в небольшой табличке на листе (A4:B15).
Но у меня ситуация такая, что часть месяцев в столбце E, а именно - сентябрь, ноябрь, март - написаны не в три буквы, а в четыре.
то есть сент (вместо сен), нояб (вместо ноя), март (вместо мар).

То есть формат ДДМММГГГГ - не воспринимает такую запись.

Как изменить формулу, чтобы она и для месяцев записанных в 4 буквы - также определяла - сколько времени осталось до даты (Ячейка L2) или сколько времени с этой даты прошло ?
К сообщению приложен файл: 0877935.xls (74.0 Kb)
 
Ответить
СообщениеЗдравствуйте.
У меня такой вопрос:

Есть формула определяющая - сколько дней осталось до определенной даты, или же сколько дней прошло.

Формула меняет месяцы, в соответствии со списком - в небольшой табличке на листе (A4:B15).
Но у меня ситуация такая, что часть месяцев в столбце E, а именно - сентябрь, ноябрь, март - написаны не в три буквы, а в четыре.
то есть сент (вместо сен), нояб (вместо ноя), март (вместо мар).

То есть формат ДДМММГГГГ - не воспринимает такую запись.

Как изменить формулу, чтобы она и для месяцев записанных в 4 буквы - также определяла - сколько времени осталось до даты (Ячейка L2) или сколько времени с этой даты прошло ?

Автор - SergVrn
Дата добавления - 03.11.2018 в 05:15
Pelena Дата: Суббота, 03.11.2018, 08:47 | Сообщение № 2
Группа: Админы
Ранг: Местный житель
Сообщений: 19161
Репутация: 4412 ±
Замечаний: ±

Excel 365 & Mac Excel
Здравствуйте.
Как вариант
Код
=--(ЕСЛИОШИБКА(--ЛЕВСИМВ(E4;2);--ЛЕВСИМВ(E4;1))&"-"&ПСТР(E4;ДЛСТР(ЕСЛИОШИБКА(--ЛЕВСИМВ(E4;2);--ЛЕВСИМВ(E4;1)))+1;3)&"-"&ПРАВСИМВ(E4;4))-ЗАМЕНИТЬ(ЗАМЕНИТЬ($L$2;ДЛСТР($L$2)-6;;"-");ДЛСТР($L$2)-2;;"-")
К сообщению приложен файл: 6120121.xls (74.5 Kb)


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеЗдравствуйте.
Как вариант
Код
=--(ЕСЛИОШИБКА(--ЛЕВСИМВ(E4;2);--ЛЕВСИМВ(E4;1))&"-"&ПСТР(E4;ДЛСТР(ЕСЛИОШИБКА(--ЛЕВСИМВ(E4;2);--ЛЕВСИМВ(E4;1)))+1;3)&"-"&ПРАВСИМВ(E4;4))-ЗАМЕНИТЬ(ЗАМЕНИТЬ($L$2;ДЛСТР($L$2)-6;;"-");ДЛСТР($L$2)-2;;"-")

Автор - Pelena
Дата добавления - 03.11.2018 в 08:47
_Igor_61 Дата: Суббота, 03.11.2018, 08:55 | Сообщение № 3
Группа: Проверенные
Ранг: Ветеран
Сообщений: 504
Репутация: 90 ±
Замечаний: 0% ±

Excel 2007
SergVrn, а ведь обещали :)
 
Ответить
СообщениеSergVrn, а ведь обещали :)

Автор - _Igor_61
Дата добавления - 03.11.2018 в 08:55
gling Дата: Суббота, 03.11.2018, 09:46 | Сообщение № 4
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2519
Репутация: 674 ±
Замечаний: 0% ±

2010
Здравствуйте. Еще вариант
Код
=ДАТА(ПРАВБ(E4;4);ВПР(ПСТР(E4;ДЛСТР(E4)-(6+ЕОШ(--ЛЕВБ(E4;ДЛСТР(E4)-7)));3);$A$4:$B$15;2;0);ЛЕВБ(E4;ДЛСТР(E4)-(7+ЕОШ(--ЛЕВБ(E4;ДЛСТР(E4)-7)))))-$L$2


ЯД-41001506838083
 
Ответить
СообщениеЗдравствуйте. Еще вариант
Код
=ДАТА(ПРАВБ(E4;4);ВПР(ПСТР(E4;ДЛСТР(E4)-(6+ЕОШ(--ЛЕВБ(E4;ДЛСТР(E4)-7)));3);$A$4:$B$15;2;0);ЛЕВБ(E4;ДЛСТР(E4)-(7+ЕОШ(--ЛЕВБ(E4;ДЛСТР(E4)-7)))))-$L$2

Автор - gling
Дата добавления - 03.11.2018 в 09:46
bmv98rus Дата: Суббота, 03.11.2018, 09:53 | Сообщение № 5
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4098
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
длинно, но без допов. и без ограничений, которые нашел
Код
="Осталось "&DATE(RIGHT(TRIM(E4);4);MIN(IF(ISNUMBER(FIND(TEXT(--("1/"&{1;2;3;4;5;6;7;8;9;10;11;12}&"/1");"МММ");E4));{1;2;3;4;5;6;7;8;9;10;11;12}));IFERROR(--LEFT(TRIM(E4);2);--LEFT(TRIM(E4);1)))-DATE(RIGHT(TRIM($L$2);4);MIN(IF(ISNUMBER(FIND(TEXT(--("1/"&{1;2;3;4;5;6;7;8;9;10;11;12}&"/1");"МММ");$L$2));{1;2;3;4;5;6;7;8;9;10;11;12}));IFERROR(--LEFT(TRIM($L$2);2);--LEFT(TRIM($L$2);1)))&"дн"

Если не смущает формула массива, то тоже самое но чуть короче
Код
="Осталось "&DATE(RIGHT(TRIM(E4);4);MIN(IF(ISNUMBER(FIND(TEXT(--("1/"&ROW(1:12)&"/1");"МММ");E4));ROW(1:12)));IFERROR(--LEFT(TRIM(E4);2);--LEFT(TRIM(E4);1)))-DATE(RIGHT(TRIM($L$2);4);MIN(IF(ISNUMBER(FIND(TEXT(--("1/"&ROW(1:12)&"/1");"МММ");$L$2));ROW(1:12)));IFERROR(--LEFT(TRIM($L$2);2);--LEFT(TRIM($L$2);1)))&"дн"
К сообщению приложен файл: Copy_of_416_1.xlsx (19.5 Kb)


Замечательный Временно просто медведь , процентов на 20.

Сообщение отредактировал bmv98rus - Суббота, 03.11.2018, 10:11
 
Ответить
Сообщениедлинно, но без допов. и без ограничений, которые нашел
Код
="Осталось "&DATE(RIGHT(TRIM(E4);4);MIN(IF(ISNUMBER(FIND(TEXT(--("1/"&{1;2;3;4;5;6;7;8;9;10;11;12}&"/1");"МММ");E4));{1;2;3;4;5;6;7;8;9;10;11;12}));IFERROR(--LEFT(TRIM(E4);2);--LEFT(TRIM(E4);1)))-DATE(RIGHT(TRIM($L$2);4);MIN(IF(ISNUMBER(FIND(TEXT(--("1/"&{1;2;3;4;5;6;7;8;9;10;11;12}&"/1");"МММ");$L$2));{1;2;3;4;5;6;7;8;9;10;11;12}));IFERROR(--LEFT(TRIM($L$2);2);--LEFT(TRIM($L$2);1)))&"дн"

Если не смущает формула массива, то тоже самое но чуть короче
Код
="Осталось "&DATE(RIGHT(TRIM(E4);4);MIN(IF(ISNUMBER(FIND(TEXT(--("1/"&ROW(1:12)&"/1");"МММ");E4));ROW(1:12)));IFERROR(--LEFT(TRIM(E4);2);--LEFT(TRIM(E4);1)))-DATE(RIGHT(TRIM($L$2);4);MIN(IF(ISNUMBER(FIND(TEXT(--("1/"&ROW(1:12)&"/1");"МММ");$L$2));ROW(1:12)));IFERROR(--LEFT(TRIM($L$2);2);--LEFT(TRIM($L$2);1)))&"дн"

Автор - bmv98rus
Дата добавления - 03.11.2018 в 09:53
AlexM Дата: Суббота, 03.11.2018, 12:57 | Сообщение № 6
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4448
Репутация: 1094 ±
Замечаний: 0% ±

Excel 2003
Код
=(-ПРОСМОТР(;-ЛЕВБ(E4;{1;2}))&ПСТР(E4;ДЛСТР(-ПРОСМОТР(;-ЛЕВБ(E4;{1;2})))+1;3)&ПРАВБ(E4;4))-L$2
К сообщению приложен файл: 0877935_01.xls (77.5 Kb)



Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.
 
Ответить
Сообщение
Код
=(-ПРОСМОТР(;-ЛЕВБ(E4;{1;2}))&ПСТР(E4;ДЛСТР(-ПРОСМОТР(;-ЛЕВБ(E4;{1;2})))+1;3)&ПРАВБ(E4;4))-L$2

Автор - AlexM
Дата добавления - 03.11.2018 в 12:57
Светлый Дата: Суббота, 03.11.2018, 14:34 | Сообщение № 7
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
Формула массива:
Код
=МАКС(ЕСЛИОШИБКА(ДАТА(ПРАВБ(E4;4);(ПОИСК(A$4:A$15;E4)>0)*B$4:B$15;ЛЕВБ(E4;{1;2}));))-L$2
*Или вообще без дополнительной таблицы названий:
Код
=МАКС(ЕСЛИОШИБКА(ДАТА(ПРАВБ(E4;4);(ПОИСК(ТЕКСТ(СТРОКА($1:$12)*30;"МММ");E4)>0)*СТРОКА($1:$12);ЛЕВБ(E4;{1;2}));))-L$2


Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Суббота, 03.11.2018, 15:02
 
Ответить
СообщениеФормула массива:
Код
=МАКС(ЕСЛИОШИБКА(ДАТА(ПРАВБ(E4;4);(ПОИСК(A$4:A$15;E4)>0)*B$4:B$15;ЛЕВБ(E4;{1;2}));))-L$2
*Или вообще без дополнительной таблицы названий:
Код
=МАКС(ЕСЛИОШИБКА(ДАТА(ПРАВБ(E4;4);(ПОИСК(ТЕКСТ(СТРОКА($1:$12)*30;"МММ");E4)>0)*СТРОКА($1:$12);ЛЕВБ(E4;{1;2}));))-L$2

Автор - Светлый
Дата добавления - 03.11.2018 в 14:34
Светлый Дата: Суббота, 03.11.2018, 17:16 | Сообщение № 8
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
чтобы она и для месяцев записанных в 4 буквы
Для таких условий массивная формула:
Код
=ЗАМЕНИТЬ(E4;ДЛСТР(E4)-4;1-ИЛИ(ЛЕВБ(ПРАВБ(E4;7);3)=A$4:A$15);)-L$2
Или так:
Код
=ЗАМЕНИТЬ(E4;ДЛСТР(E4)-4;И(ЛЕВБ(ПРАВБ(E4;7);3)<>A$4:A$15);)-L$2
и немассивная:
Код
=ЗАМЕНИТЬ(E4;ДЛСТР(E4)-4;1-СЧЁТЕСЛИ(A$4:A$15;ЛЕВБ(ПРАВБ(E4;7);3));)-L$2


Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Суббота, 03.11.2018, 19:49
 
Ответить
Сообщение
чтобы она и для месяцев записанных в 4 буквы
Для таких условий массивная формула:
Код
=ЗАМЕНИТЬ(E4;ДЛСТР(E4)-4;1-ИЛИ(ЛЕВБ(ПРАВБ(E4;7);3)=A$4:A$15);)-L$2
Или так:
Код
=ЗАМЕНИТЬ(E4;ДЛСТР(E4)-4;И(ЛЕВБ(ПРАВБ(E4;7);3)<>A$4:A$15);)-L$2
и немассивная:
Код
=ЗАМЕНИТЬ(E4;ДЛСТР(E4)-4;1-СЧЁТЕСЛИ(A$4:A$15;ЛЕВБ(ПРАВБ(E4;7);3));)-L$2

Автор - Светлый
Дата добавления - 03.11.2018 в 17:16
gling Дата: Воскресенье, 04.11.2018, 00:11 | Сообщение № 9
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2519
Репутация: 674 ±
Замечаний: 0% ±

2010
А может так, без заморочек?
Код
=--E4-L$2
Код
="Осталось "&--E4-$L$2&"дн"


ЯД-41001506838083

Сообщение отредактировал gling - Воскресенье, 04.11.2018, 01:28
 
Ответить
СообщениеА может так, без заморочек?
Код
=--E4-L$2
Код
="Осталось "&--E4-$L$2&"дн"

Автор - gling
Дата добавления - 04.11.2018 в 00:11
Светлый Дата: Воскресенье, 04.11.2018, 00:44 | Сообщение № 10
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
И кто бы мог догадаться? :o
Код
=E4-L$2
Правда, в других версиях офиса не пробовал.


Программировать проще, чем писать стихи.
 
Ответить
СообщениеИ кто бы мог догадаться? :o
Код
=E4-L$2
Правда, в других версиях офиса не пробовал.

Автор - Светлый
Дата добавления - 04.11.2018 в 00:44
SergVrn Дата: Понедельник, 05.11.2018, 07:44 | Сообщение № 11
Группа: Пользователи
Ранг: Участник
Сообщений: 87
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Всем большое спасибо за ответы.
 
Ответить
СообщениеВсем большое спасибо за ответы.

Автор - SergVrn
Дата добавления - 05.11.2018 в 07:44
bmv98rus Дата: Понедельник, 05.11.2018, 08:57 | Сообщение № 12
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4098
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
gling, #2 :-)
Цитата Светлый, 04.11.2018 в 00:44, в сообщении № 10 ()
кто бы мог догадаться?

Ну правда все это работает только при совпадении региональных установок. в #5 достаточно изменить "МММ" на "[$-en-US]МММ" и 5Nove2018 будет обработано корректно.


Замечательный Временно просто медведь , процентов на 20.
 
Ответить
Сообщениеgling, #2 :-)
Цитата Светлый, 04.11.2018 в 00:44, в сообщении № 10 ()
кто бы мог догадаться?

Ну правда все это работает только при совпадении региональных установок. в #5 достаточно изменить "МММ" на "[$-en-US]МММ" и 5Nove2018 будет обработано корректно.

Автор - bmv98rus
Дата добавления - 05.11.2018 в 08:57
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Формула не выдает результат при записи месяца в 4 буквы (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!