Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Сравнить 2 табл с 3 столбцами, вывести ответ в 4ый - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Сравнить 2 табл с 3 столбцами, вывести ответ в 4ый (Формулы/Formulas)
Сравнить 2 табл с 3 столбцами, вывести ответ в 4ый
DAKRAY Дата: Среда, 06.03.2019, 12:20 | Сообщение № 1
Группа: Пользователи
Ранг: Участник
Сообщений: 73
Репутация: 1 ±
Замечаний: 0% ±

Excel 2003
Всем привет!

3 столбца с размерами A, B, C (в 4м столбце D - кол-во). Надо сравнить с 3 столбцами E, F, G и при совпадение в столбец D вписать кол-во из стобца H.
E, F, G, H - у меня файл со складом, A, B, C, D - бланк заказа, суть задачи - записываю новый заказ и сразу вижу сколько штук есть на складе.
Я в формуле, в месте "value_if true" прописал диапазон "H$2:H$11", но он выводит в ответ не кол-во штук у найденого сопадения, а кол-во которое в строке, где находится формула. Так же не понимаю, почему выводит ответ, если в стобцах A, B, C пусто? Ну это я думаю решу расширив фнцю IF'ом.
Помогите, пжл, разобраться.

Файл пример в приложении.

Заранее спасибо!

П.С. Не ругайте, что тема похожая уже была, написал в ней, дабы не повторяться, но она закрыта!
К сообщению приложен файл: 1_new2.xls (18.0 Kb)


Сообщение отредактировал DAKRAY - Среда, 06.03.2019, 12:26
 
Ответить
СообщениеВсем привет!

3 столбца с размерами A, B, C (в 4м столбце D - кол-во). Надо сравнить с 3 столбцами E, F, G и при совпадение в столбец D вписать кол-во из стобца H.
E, F, G, H - у меня файл со складом, A, B, C, D - бланк заказа, суть задачи - записываю новый заказ и сразу вижу сколько штук есть на складе.
Я в формуле, в месте "value_if true" прописал диапазон "H$2:H$11", но он выводит в ответ не кол-во штук у найденого сопадения, а кол-во которое в строке, где находится формула. Так же не понимаю, почему выводит ответ, если в стобцах A, B, C пусто? Ну это я думаю решу расширив фнцю IF'ом.
Помогите, пжл, разобраться.

Файл пример в приложении.

Заранее спасибо!

П.С. Не ругайте, что тема похожая уже была, написал в ней, дабы не повторяться, но она закрыта!

Автор - DAKRAY
Дата добавления - 06.03.2019 в 12:20
китин Дата: Среда, 06.03.2019, 12:27 | Сообщение № 2
Группа: Модераторы
Ранг: Экселист
Сообщений: 7013
Репутация: 1073 ±
Замечаний: 0% ±

Excel 2007;2010;2016
Доброго времени!!!
формула масива
Код
=ЕСЛИОШИБКА(ИНДЕКС($H$2:$H$11;ПОИСКПОЗ(A2&B2&C2;$E$2:$E$11&$F$2:$F$11&$G$2:$G$11;0));"Нет")
К сообщению приложен файл: 1_new2.xlsx (12.2 Kb)


Не судите очень строго:я пытаюсь научиться
ЯД 41001877306852
 
Ответить
СообщениеДоброго времени!!!
формула масива
Код
=ЕСЛИОШИБКА(ИНДЕКС($H$2:$H$11;ПОИСКПОЗ(A2&B2&C2;$E$2:$E$11&$F$2:$F$11&$G$2:$G$11;0));"Нет")

Автор - китин
Дата добавления - 06.03.2019 в 12:27
_Boroda_ Дата: Среда, 06.03.2019, 12:40 | Сообщение № 3
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16666
Репутация: 6478 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Еще вариант
Код
=СУММЕСЛИМН(H:H;E:E;A2;F:F;B2;G:G;C2)

Можно поставить формат
0;;нет

* Не заметил, что 2003 Excel
Тогда
Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/(A2&B2&C2=E$2:E$99&F$2:F$99&G$2:G$99);H$2:H$99);"нет")


** Стормозил. ЕСЛИОШИБКА - не 2003
К сообщению приложен файл: 1_new2_1.xls (43.0 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеЕще вариант
Код
=СУММЕСЛИМН(H:H;E:E;A2;F:F;B2;G:G;C2)

Можно поставить формат
0;;нет

* Не заметил, что 2003 Excel
Тогда
Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/(A2&B2&C2=E$2:E$99&F$2:F$99&G$2:G$99);H$2:H$99);"нет")


** Стормозил. ЕСЛИОШИБКА - не 2003

Автор - _Boroda_
Дата добавления - 06.03.2019 в 12:40
DAKRAY Дата: Среда, 06.03.2019, 12:57 | Сообщение № 4
Группа: Пользователи
Ранг: Участник
Сообщений: 73
Репутация: 1 ±
Замечаний: 0% ±

Excel 2003
китин, у меня 2003ий((. Формула не работает, попробовал вместо IFERROR написать ISERROR (вроде как так должно быть), но пишет, что слишком много аргументов.

_Boroda_, попробовал вставить формулу не работает. Посмотрел пример - появились стобцы I и J, мне надо чтобы вот тот ответ что у Вас в столбце J отображалось в столбце D, а там сейчас моя не правильная формула стоит. Попробовал вставить Вашу в столбец D, пишет #NAME.(
 
Ответить
Сообщениекитин, у меня 2003ий((. Формула не работает, попробовал вместо IFERROR написать ISERROR (вроде как так должно быть), но пишет, что слишком много аргументов.

_Boroda_, попробовал вставить формулу не работает. Посмотрел пример - появились стобцы I и J, мне надо чтобы вот тот ответ что у Вас в столбце J отображалось в столбце D, а там сейчас моя не правильная формула стоит. Попробовал вставить Вашу в столбец D, пишет #NAME.(

Автор - DAKRAY
Дата добавления - 06.03.2019 в 12:57
_Boroda_ Дата: Среда, 06.03.2019, 13:05 | Сообщение № 5
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16666
Репутация: 6478 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Да, конечно, ЕСЛИОШИБКА - это не для 2003
Вот так
Код
=ЕСЛИ(ЕЧИСЛО(ПРОСМОТР(;-1/(A2&B2&C2=E$2:E$99&F$2:F$99&G$2:G$99);H$2:H$99));ПРОСМОТР(;-1/(A2&B2&C2=E$2:E$99&F$2:F$99&G$2:G$99);H$2:H$99);"нет")

Или так
Код
=СУММПРОИЗВ((E$2:E$11=A2)*(F$2:F$11=B2)*(G$2:G$11=C2)*H$2:H$11)
К сообщению приложен файл: 1_new2_2.xls (42.0 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеДа, конечно, ЕСЛИОШИБКА - это не для 2003
Вот так
Код
=ЕСЛИ(ЕЧИСЛО(ПРОСМОТР(;-1/(A2&B2&C2=E$2:E$99&F$2:F$99&G$2:G$99);H$2:H$99));ПРОСМОТР(;-1/(A2&B2&C2=E$2:E$99&F$2:F$99&G$2:G$99);H$2:H$99);"нет")

Или так
Код
=СУММПРОИЗВ((E$2:E$11=A2)*(F$2:F$11=B2)*(G$2:G$11=C2)*H$2:H$11)

Автор - _Boroda_
Дата добавления - 06.03.2019 в 13:05
китин Дата: Среда, 06.03.2019, 13:29 | Сообщение № 6
Группа: Модераторы
Ранг: Экселист
Сообщений: 7013
Репутация: 1073 ±
Замечаний: 0% ±

Excel 2007;2010;2016
у меня 2003ий


ну да, не заметил
Код
=ЕСЛИ(ЕОШИБКА(ИНДЕКС($H$2:$H$11;ПОИСКПОЗ(A2&B2&C2;$E$2:$E$11&$F$2:$F$11&$G$2:$G$11;0)));"Нет";ИНДЕКС($H$2:$H$11;ПОИСКПОЗ(A2&B2&C2;$E$2:$E$11&$F$2:$F$11&$G$2:$G$11;0)))

тоже массивная
К сообщению приложен файл: 22_new2.xls (26.0 Kb)


Не судите очень строго:я пытаюсь научиться
ЯД 41001877306852
 
Ответить
Сообщение
у меня 2003ий


ну да, не заметил
Код
=ЕСЛИ(ЕОШИБКА(ИНДЕКС($H$2:$H$11;ПОИСКПОЗ(A2&B2&C2;$E$2:$E$11&$F$2:$F$11&$G$2:$G$11;0)));"Нет";ИНДЕКС($H$2:$H$11;ПОИСКПОЗ(A2&B2&C2;$E$2:$E$11&$F$2:$F$11&$G$2:$G$11;0)))

тоже массивная

Автор - китин
Дата добавления - 06.03.2019 в 13:29
DAKRAY Дата: Среда, 06.03.2019, 14:09 | Сообщение № 7
Группа: Пользователи
Ранг: Участник
Сообщений: 73
Репутация: 1 ±
Замечаний: 0% ±

Excel 2003
_Boroda_, китин спасибо за оперативность и за рабочие ответы!

Идеально!
Остановился на этом варианте:
Или так

=СУММПРОИЗВ((E$2:E$11=A2)*(F$2:F$11=B2)*(G$2:G$11=C2)*H$2:H$11)

мне чем короче тем лучше, ибо в реальной ситуации у меня эти таблички в разных книгах и формула соответсвенно станет еще длинней.

Низкий поклон!

З.Ы. Красота!!! Сравнивая таблицы между книгами все работает отлично!!!


Сообщение отредактировал DAKRAY - Среда, 06.03.2019, 14:29
 
Ответить
Сообщение_Boroda_, китин спасибо за оперативность и за рабочие ответы!

Идеально!
Остановился на этом варианте:
Или так

=СУММПРОИЗВ((E$2:E$11=A2)*(F$2:F$11=B2)*(G$2:G$11=C2)*H$2:H$11)

мне чем короче тем лучше, ибо в реальной ситуации у меня эти таблички в разных книгах и формула соответсвенно станет еще длинней.

Низкий поклон!

З.Ы. Красота!!! Сравнивая таблицы между книгами все работает отлично!!!

Автор - DAKRAY
Дата добавления - 06.03.2019 в 14:09
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Сравнить 2 табл с 3 столбцами, вывести ответ в 4ый (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!