Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Отображение фамилий в таблице, из графика смен - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Отображение фамилий в таблице, из графика смен (Формулы/Formulas)
Отображение фамилий в таблице, из графика смен
Maksimys07 Дата: Воскресенье, 01.12.2019, 21:56 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 20% ±

Excel 2016
ДВС!Пытаюсь сделать автоматический список фамилий, который берет значения с графика смен. Нужная помощь с формулой для этого списка! файл прилагаю.
К сообщению приложен файл: 12-2-.xlsx (21.2 Kb)
 
Ответить
СообщениеДВС!Пытаюсь сделать автоматический список фамилий, который берет значения с графика смен. Нужная помощь с формулой для этого списка! файл прилагаю.

Автор - Maksimys07
Дата добавления - 01.12.2019 в 21:56
Pelena Дата: Воскресенье, 01.12.2019, 23:38 | Сообщение № 2
Группа: Админы
Ранг: Местный житель
Сообщений: 19162
Репутация: 4412 ±
Замечаний: ±

Excel 365 & Mac Excel
Здравствуйте.
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$14:$B$18;ПОИСКПОЗ("д";ИНДЕКС($D$14:$AH$18;0;AK5);0));"")
К сообщению приложен файл: 12_1.xlsx (21.6 Kb)


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеЗдравствуйте.
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$14:$B$18;ПОИСКПОЗ("д";ИНДЕКС($D$14:$AH$18;0;AK5);0));"")

Автор - Pelena
Дата добавления - 01.12.2019 в 23:38
_Boroda_ Дата: Понедельник, 02.12.2019, 08:37 | Сообщение № 3
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16666
Репутация: 6478 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Еще варианты
В 1, 11 и 21 числах написано не "д", а "д "
Если поправить, то
Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/("д"=ИНДЕКС(D$14:AH$18;;AM5));B$14:B$18);"")

Если не править, то
Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-ПОИСК("д";ИНДЕКС(D$14:AH$18;;AM5));B$14:B$18);"")
К сообщению приложен файл: 12-3-1_1.xlsx (19.7 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеЕще варианты
В 1, 11 и 21 числах написано не "д", а "д "
Если поправить, то
Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/("д"=ИНДЕКС(D$14:AH$18;;AM5));B$14:B$18);"")

Если не править, то
Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-ПОИСК("д";ИНДЕКС(D$14:AH$18;;AM5));B$14:B$18);"")

Автор - _Boroda_
Дата добавления - 02.12.2019 в 08:37
Maksimys07 Дата: Вторник, 03.12.2019, 13:58 | Сообщение № 4
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 20% ±

Excel 2016
Не обдумав до конца данный вопрос, хочу продолжить, тем самым усложнив данную задачу.
Каким образом сделать чтобы даты "д" и "т" списков проставлялись автоматически по порядку пример в списке "т" .... файл с примером прилагаю.
К сообщению приложен файл: v2.xlsx (19.2 Kb)


Сообщение отредактировал Maksimys07 - Вторник, 03.12.2019, 14:00
 
Ответить
СообщениеНе обдумав до конца данный вопрос, хочу продолжить, тем самым усложнив данную задачу.
Каким образом сделать чтобы даты "д" и "т" списков проставлялись автоматически по порядку пример в списке "т" .... файл с примером прилагаю.

Автор - Maksimys07
Дата добавления - 03.12.2019 в 13:58
bigor Дата: Вторник, 03.12.2019, 16:55 | Сообщение № 5
Группа: Проверенные
Ранг: Старожил
Сообщений: 1073
Репутация: 204 ±
Замечаний: 0% ±

нет
Для т
Код
=IFERROR(INDEX($A$12:$AH$12;1;SMALL(IF($A$15:$AH$15=$AM$2;COLUMN($A$15:$AH$15);1000);ROW(A1)));"")


Сообщение отредактировал bigor - Вторник, 03.12.2019, 16:57
 
Ответить
СообщениеДля т
Код
=IFERROR(INDEX($A$12:$AH$12;1;SMALL(IF($A$15:$AH$15=$AM$2;COLUMN($A$15:$AH$15);1000);ROW(A1)));"")

Автор - bigor
Дата добавления - 03.12.2019 в 16:55
jakim Дата: Вторник, 03.12.2019, 19:31 | Сообщение № 6
Группа: Друзья
Ранг: Старожил
Сообщений: 1197
Репутация: 313 ±
Замечаний: 0% ±

Excel 2010
Предлагаю вариант с формулами для
дат

Код
=IFERROR(AGGREGATE(15;6;D$12:AH$12/(D$14:AH$18="т");ROWS($5:5));"")

фамилий

Код
=IFERROR(INDEX(B$14:B$18;AGGREGATE(15;6;ROW($1:$20)/(D$14:AH$18="т");ROWS($5:5)));"")
К сообщению приложен файл: 1632274.xlsx (19.2 Kb)
 
Ответить
Сообщение
Предлагаю вариант с формулами для
дат

Код
=IFERROR(AGGREGATE(15;6;D$12:AH$12/(D$14:AH$18="т");ROWS($5:5));"")

фамилий

Код
=IFERROR(INDEX(B$14:B$18;AGGREGATE(15;6;ROW($1:$20)/(D$14:AH$18="т");ROWS($5:5)));"")

Автор - jakim
Дата добавления - 03.12.2019 в 19:31
_Boroda_ Дата: Вторник, 03.12.2019, 20:17 | Сообщение № 7
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16666
Репутация: 6478 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Maksimys07, буква Т может же быть наверняка не только у Сочнева, правильно? И могут ли одинаковый буквы быть у нескольких людей в один день?
Предлагаю так
Для дат
Код
=НАИМЕНЬШИЙ(--ТЕКСТ(($D$14:$AH$18=AM$2)*$D$12:$AH$12;"Д;;99");СТРОКА(AM1))

Для ФИО
Код
=ЕСЛИ(AM5=99;"";ИНДЕКС($B$14:$B$18;(НАИМЕНЬШИЙ($A$14:$A$18%+ТЕКСТ(($D$14:$AH$18=AM$2)*$D$12:$AH$12;"Д;;99");СТРОКА(AM1))-AM5)/1%))

Обе формулы массива. Вводятся одновременным нажатием Контрл Шифт Ентер
Всякие лишности в столбцах дат скрыты условным форматированием
К сообщению приложен файл: v2_1.xlsx (22.3 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеMaksimys07, буква Т может же быть наверняка не только у Сочнева, правильно? И могут ли одинаковый буквы быть у нескольких людей в один день?
Предлагаю так
Для дат
Код
=НАИМЕНЬШИЙ(--ТЕКСТ(($D$14:$AH$18=AM$2)*$D$12:$AH$12;"Д;;99");СТРОКА(AM1))

Для ФИО
Код
=ЕСЛИ(AM5=99;"";ИНДЕКС($B$14:$B$18;(НАИМЕНЬШИЙ($A$14:$A$18%+ТЕКСТ(($D$14:$AH$18=AM$2)*$D$12:$AH$12;"Д;;99");СТРОКА(AM1))-AM5)/1%))

Обе формулы массива. Вводятся одновременным нажатием Контрл Шифт Ентер
Всякие лишности в столбцах дат скрыты условным форматированием

Автор - _Boroda_
Дата добавления - 03.12.2019 в 20:17
Maksimys07 Дата: Воскресенье, 08.12.2019, 00:33 | Сообщение № 8
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 20% ±

Excel 2016
Для ФИО без данного диапазона $A$14:$A$18 нельзя обойтись, если в таблица будет с пропуском строки, если разбиваешь это диапазон на несколько выдает ошибку "большой аргумент"
К сообщению приложен файл: v2_1_2.xlsx (22.2 Kb)
 
Ответить
СообщениеДля ФИО без данного диапазона $A$14:$A$18 нельзя обойтись, если в таблица будет с пропуском строки, если разбиваешь это диапазон на несколько выдает ошибку "большой аргумент"

Автор - Maksimys07
Дата добавления - 08.12.2019 в 00:33
_Boroda_ Дата: Воскресенье, 08.12.2019, 18:16 | Сообщение № 9
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16666
Репутация: 6478 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Так нужно?
Код
=ЕСЛИ(AM5=99;"";ИНДЕКС($B:$B;(НАИМЕНЬШИЙ(СТРОКА($14:$19)%+ТЕКСТ(($D$14:$AH$19=AM$2)*$D$12:$AH$12;"Д;;99");СТРОКА(AM1))-AM5)/1%))
К сообщению приложен файл: v2_1_2_1.xlsx (22.7 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеТак нужно?
Код
=ЕСЛИ(AM5=99;"";ИНДЕКС($B:$B;(НАИМЕНЬШИЙ(СТРОКА($14:$19)%+ТЕКСТ(($D$14:$AH$19=AM$2)*$D$12:$AH$12;"Д;;99");СТРОКА(AM1))-AM5)/1%))

Автор - _Boroda_
Дата добавления - 08.12.2019 в 18:16
Maksimys07 Дата: Понедельник, 09.12.2019, 20:56 | Сообщение № 10
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 20% ±

Excel 2016
Да именно так, всем спасибо! Еще бы понять как эта формула работает, если не сложно распишите по подробнее.
 
Ответить
СообщениеДа именно так, всем спасибо! Еще бы понять как эта формула работает, если не сложно распишите по подробнее.

Автор - Maksimys07
Дата добавления - 09.12.2019 в 20:56
_Boroda_ Дата: Понедельник, 09.12.2019, 22:04 | Сообщение № 11
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16666
Репутация: 6478 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Если в двух словах, то
1. ($D$14:$AH$19=AM$2)*$D$12:$AH$12 - когда в диапазоне $D$14:$AH$19 написано "т", то ИСТИНА, иначе - ЛОЖЬ. Умножив все это на даты из строки 12, получим или даты, или ноль
2. ТЕКСТ(п.1;"Д;;99") - если в п.1 дата, то от нее берем только день, если ноль, то преобразуем его в 99
3. СТРОКА($14:$19)% +п.2 - номера строк 14-19 делим на 100 (знак %) и прибавляем к полученному в п.2, получаем дни с номерами строк (типа вот так 12,14 для "т" в 12 числе и в 14 строке) или 99 с теми же номерами строк
4. НАИМЕНЬШИЙ(п.3);СТРОКА(AM1)) - из всей это кучи берем такой наименьший, какой значение дает нам функция СТРОКА. Для АМ1 это будет 1, для АМ2 - 2 и т.д.. То есть это будет какое-то число типа 12,14
5. п.4 - АМ5 - вычитаем из п.4 дату из АМ, получаем только дробную часть из п.4, т.е из 12,14 получаем 0,14
6. п.5 / 1% - делим на 1%, это все равно, что умножаем на 100 (почти все равно, может влезть ошибка округления в 13 знаке после запятой. но сейчас это не так важно), из 0,14 получаем 14 - это номер искомой строки
7. ИНДЕКС($B:$B;п.6) - из значений столбца В вынимаем то, у которого номер строки был нами только что найден в п.6
8. ЕСЛИ(AM5=99;"";... - если в АМ 99 (что это такое - см. в п.2), то пишем пусто, иначе - расчет, приведенный выше


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеЕсли в двух словах, то
1. ($D$14:$AH$19=AM$2)*$D$12:$AH$12 - когда в диапазоне $D$14:$AH$19 написано "т", то ИСТИНА, иначе - ЛОЖЬ. Умножив все это на даты из строки 12, получим или даты, или ноль
2. ТЕКСТ(п.1;"Д;;99") - если в п.1 дата, то от нее берем только день, если ноль, то преобразуем его в 99
3. СТРОКА($14:$19)% +п.2 - номера строк 14-19 делим на 100 (знак %) и прибавляем к полученному в п.2, получаем дни с номерами строк (типа вот так 12,14 для "т" в 12 числе и в 14 строке) или 99 с теми же номерами строк
4. НАИМЕНЬШИЙ(п.3);СТРОКА(AM1)) - из всей это кучи берем такой наименьший, какой значение дает нам функция СТРОКА. Для АМ1 это будет 1, для АМ2 - 2 и т.д.. То есть это будет какое-то число типа 12,14
5. п.4 - АМ5 - вычитаем из п.4 дату из АМ, получаем только дробную часть из п.4, т.е из 12,14 получаем 0,14
6. п.5 / 1% - делим на 1%, это все равно, что умножаем на 100 (почти все равно, может влезть ошибка округления в 13 знаке после запятой. но сейчас это не так важно), из 0,14 получаем 14 - это номер искомой строки
7. ИНДЕКС($B:$B;п.6) - из значений столбца В вынимаем то, у которого номер строки был нами только что найден в п.6
8. ЕСЛИ(AM5=99;"";... - если в АМ 99 (что это такое - см. в п.2), то пишем пусто, иначе - расчет, приведенный выше

Автор - _Boroda_
Дата добавления - 09.12.2019 в 22:04
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Отображение фамилий в таблице, из графика смен (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!