Option Explicit
Private Type DOCINFO
    pDocName As String
    pOutputFile As String
    pDatatype As String
End Type
Private Declare Function ClosePrinter _
    Lib "winspool.drv" ( _
        ByVal hPrinter As Long _
    ) As Long
Private Declare Function EndDocPrinter _
    Lib "winspool.drv" ( _
        ByVal hPrinter As Long _
    ) As Long
Private Declare Function EndPagePrinter _
    Lib "winspool.drv" ( _
        ByVal hPrinter As Long _
    ) As Long
Private Declare Function OpenPrinter _
    Lib "winspool.drv" _
    Alias "OpenPrinterA" ( _
        ByVal pPrinterName As String, _
        phPrinter As Long, _
        ByVal pDefault As Long _
    ) As Long
Private Declare Function StartDocPrinter _
    Lib "winspool.drv" _
    Alias "StartDocPrinterA" ( _
        ByVal hPrinter As Long, _
        ByVal Level As Long, _
        pDocInfo As DOCINFO _
    ) As Long
Private Declare Function StartPagePrinter _
    Lib "winspool.drv" ( _
        ByVal hPrinter As Long _
    ) As Long
Private Declare Function WritePrinter _
    Lib "winspool.drv" ( _
        ByVal hPrinter As Long, _
        pBuf As Any, _
        ByVal cdBuf As Long, _
        pcWritten As Long _
    ) As Long

Public Sub PrintStr(sWrittenData As String, Optional prn As String)
    Dim lhPrinter As Long
    Dim lReturn As Long
    Dim lpcWritten As Long
    Dim lDoc As Long
    
    Dim MyDocInfo As DOCINFO
    If Len(prn) = 0 Then prn = ActivePrinter
    prn = Left(prn, InStr(prn & " (Ne", "(Ne") - 2)
    lReturn = OpenPrinter(prn, lhPrinter, 0)
    If lReturn = 0 Then
        MsgBox "Принтер не найден"
        Exit Sub
    End If
    MyDocInfo.pDocName = "AAAAAA"
    MyDocInfo.pOutputFile = vbNullString
    MyDocInfo.pDatatype = vbNullString
    lDoc = StartDocPrinter(lhPrinter, 1, MyDocInfo)
    Call StartPagePrinter(lhPrinter)
    lReturn = WritePrinter(lhPrinter, _
        ByVal (sWrittenData & vbFormFeed), _
        Len(sWrittenData), lpcWritten)
    lReturn = EndPagePrinter(lhPrinter)
    lReturn = EndDocPrinter(lhPrinter)
    lReturn = ClosePrinter(lhPrinter)
End Sub